@echo off
setlocal

REM ##### 初期設定 #####
REM Stack内のbinディレクトリパス
set STACK_BIN=bin
REM 外部実行タイムアウト時間(ms)
set PROCESS_TIMEOUT=1200000
REM ダウンロードのみ
set DOWNLOAD_ONLY=false
REM 起動時に読み込むスタックファイル
set DEFAULT_STACK_XML=


REM ##### 初期処理 #####
set CURRENT_DIR=%~dp0
if NOT "%CURRENT_DIR:~-1%" == "\" (
	set CURRENT_DIR=%CURRENT_DIR%\
)


REM ##### 実行ユーザー権限チェック #####
call "%CURRENT_DIR%%STACK_BIN%\CheckAuthority.bat"
if errorlevel 1 (
	echo 実行ユーザーにAdministrators権限がないため処理を続行できません。
	goto error
)


REM ##### javaインストールチェック #####
call "%CURRENT_DIR%%STACK_BIN%\CheckInstalledJava.bat"
if errorlevel 1 (
	echo javaがインストールされていないため処理を続行できません。
	goto error
)


REM ##### 起動 #####
cd %CURRENT_DIR%
start /min javaw -DprocessTimeout=%PROCESS_TIMEOUT% -DdownloadOnly=%DOWNLOAD_ONLY% -DdefaultStackXml=%DEFAULT_STACK_XML% -jar openstandiainstaller.jar
goto end


REM ##### エラー #####
:error
pause
goto end


REM ##### 終了処理 #####
:end
endlocal
exit
