@echo off

REM ##### 初期設定 #####
set LOOP_NUM=12
set ROOT_PASSWORD=root

REM ##### 引数取得 #####
set MYSQL_HOME=%~1
set MYSQL_SERVICE_NAME=%~2

REM ##### 初期処理 #####
if NOT "%MYSQL_HOME:~-1%" == "\" (
	set MYSQL_HOME=%MYSQL_HOME%\
)

REM ##### rootユーザーパスワード変更 #####
REM start "MySQL" "%MYSQL_HOME%bin\mysqld.exe" --no-defaults --console
"%MYSQL_HOME%bin\mysqld-nt.exe" --install "%MYSQL_SERVICE_NAME%" --defaults-file="%MYSQL_HOME%my.ini"
net start "%MYSQL_SERVICE_NAME%"
for /l %%i in (1,1,%LOOP_NUM%) do (
	ping localhost -n 10 > nul
	"%MYSQL_HOME%bin\mysqladmin.exe" -u root status 1> nul 2> nul
	if errorlevel 1 (
		"%MYSQL_HOME%bin\mysqladmin.exe" -u root -p%ROOT_PASSWORD% status 1> nul 2> nul
		if errorlevel 1 (
			if "%%i" == "%LOOP_NUM%" (
				echo MySQLの起動確認ができませんでした。
				goto end
			)
			echo MySQLの起動確認ができないためリトライします。^(%%i^)
		) else (
			echo MySQLの起動確認ができました。
			goto end
		)
	) else (
		echo MySQLの起動確認ができました。
		goto change_password
	)
)
:change_password
"%MYSQL_HOME%bin\mysqladmin.exe" -u root password %ROOT_PASSWORD%

:end
REM "%MYSQL_HOME%bin\mysqladmin.exe" -u root -p%ROOT_PASSWORD% shutdown

exit /b 0
