@echo off

REM ##### 初期設定 #####
set LOOP_NUM=12
set ROOT_PASSWORD=root

REM ##### 引数取得 #####
set MYSQL_HOME=%~1
set MYSQL_SERVICE_NAME=%~2

REM ##### 初期処理 #####
if NOT "%MYSQL_HOME:~-1%" == "\" (
	set MYSQL_HOME=%MYSQL_HOME%\
)

REM ##### MySQLの強制終了を試みる #####
REM "%MYSQL_HOME%bin\mysqladmin.exe" -u root -p%ROOT_PASSWORD% shutdown 1> nul 2> nul
net stop "%MYSQL_SERVICE_NAME%" 1> nul 2> nul
for /l %%i in (1,1,%LOOP_NUM%) do (
	ping localhost -n 5 > nul
	"%MYSQL_HOME%bin\mysqladmin.exe" -u root status 1> nul 2> nul
	if errorlevel 1 (
		echo MySQLの終了確認ができました。
		goto end
	) else (
		if "%%i" == "%LOOP_NUM%" (
			echo MySQLの終了確認ができませんでした。
			goto end
		)
		echo MySQLの終了確認ができないためリトライします。^(%%i^)
	)
)
:end

REM ##### アンインストール #####
"%MYSQL_HOME%bin\mysqld-nt.exe" --remove "%MYSQL_SERVICE_NAME%"
del /f /q "%MYSQL_HOME%COPYING"
del /f /q "%MYSQL_HOME%EXCEPTIONS-CLIENT"
del /f /q "%MYSQL_HOME%my-huge.ini"
del /f /q "%MYSQL_HOME%my-innodb-heavy-4G.ini"
del /f /q "%MYSQL_HOME%my-large.ini"
del /f /q "%MYSQL_HOME%my-medium.ini"
del /f /q "%MYSQL_HOME%my-small.ini"
rmdir /s /q "%MYSQL_HOME%bin"
rmdir /s /q "%MYSQL_HOME%Docs"
rmdir /s /q "%MYSQL_HOME%include"
rmdir /s /q "%MYSQL_HOME%lib"
rmdir /s /q "%MYSQL_HOME%mysql-test"
rmdir /s /q "%MYSQL_HOME%scripts"
rmdir /s /q "%MYSQL_HOME%share"
rmdir /s /q "%MYSQL_HOME%sql-bench"

exit /b 0
