@echo off

REM ##### 初期設定 #####
set BIN_DIR=bin
set JBOSS_EXE=run.bat

REM ##### 引数取得 #####
set PRODUCT_NAME=%1
set PRODUCT_VER=%2
set JBOSS_HOME=%~3

REM ##### 初期処理 #####
if NOT "%JBOSS_HOME:~-1%" == "\" (
	set JBOSS_HOME=%JBOSS_HOME%\
)

REM ##### バージョンチェック #####
set INSTALLED_VER=
cd "%JBOSS_HOME%%BIN_DIR%"
if not exist "%JBOSS_EXE%" (
	echo %PRODUCT_NAME%は、インストールされていません。
	goto end
)
for /f "tokens=2 delims= " %%F in ('%JBOSS_EXE% -V ^| find "build"') do (
	call :sub %%F
)
if "%INSTALLED_VER%" == "%PRODUCT_VER%" (
	echo %PRODUCT_NAME%は、最新版がインストールされています。^(Ver.%INSTALLED_VER%^)
	goto end
)
if "%INSTALLED_VER%" == "4.2.1.GA" (
	goto update
)
echo %PRODUCT_NAME%は、アップデート対象のバージョンではありません。^(Ver.%INSTALLED_VER%^)
goto end

REM ##### アップデート #####
:update
echo %PRODUCT_NAME%のアップデート処理をします。^(Ver.%INSTALLED_VER% -^> Ver.%PRODUCT_VER%^)
exit 0

:end
exit 1
REM ##### サブルーチン #####
:sub
set INSTALLED_VER=%1
exit /b
