[ < ] | [ > ] |  | [ << ] | [上] | [ >> ] |  |  |  |  | [冒頭] | [目次] | [見出し] | [ ? ]

# 12. Plotting

[ < ] | [ > ] |  | [ << ] | [上] | [ >> ] |  |  |  |  | [冒頭] | [目次] | [見出し] | [ ? ]

## 12.1 Introduction to Plotting

Maximaはプロットするために外部のプロットパッケージを使います。 （以下のPlottingフォーマットを参照してください）。 プロット関数は点一式を計算し、コマンド一式と一緒にプロットパッケージに渡します。 その情報は、 パイプを通したり データが保存されたファイル名と共にプログラムをコールしたりして 外部のプログラムに渡されます。 データファイルの名前は `maxout.interface`です。 `interface`は使用するプロットインターフェース名 (gnuplotか, xmaxima, mgnuplot, gnuplot_pipes)です。

グラフィック形式ファイルでプロットを保存するのに使うことができるオプションがあります。 それらの場合、ファイル `maxout.interface`が生成され、 外部のプロットプログラムが結果を他のファイルに保存するためにそれを実行します; デフォルト名 `maxplot.format`を使います。ここで `format`は使われるフォーマットです。

`maxout.interface`と `maxplot.format`ファイル(もしくはオプションで与えられたプロット名)は、 それらが使われる場合、システム変数 `maxima_tempdir` が指定するディレクトリに生成されます。 Maximaが新規ファルを生成できる有効なディレクトリを示す文字列を その変数(もしくは環境変数 MAXIMA_TEMPDIR)に割り当てることで、 その場所は変更可能です。 生成されたファイル名はプロットコマンドの出力として表示されます。

プロットを生成した後でも、 ファイル`maxout.interface`は、 適切な外部のプログラムで再度実行することができます。 もし Maximaのプロットコマンドが何かを表示するのに失敗したなら、 問題の可能性のある元をファイルで調べることができます。

この章で記述されたプロット関数と合わせて、 パッケージ `draw` は他の機能を追加します。 いくつかのプロットオプションはどちらのプロット文脈でも同じ名前が付けられていますが、 異なる構文を持つことに注意してください; もしこれらのオプションに関係した描画情報をアクセスしたいなら、 きっと `?? opt`とタイプするでしょう。ここで `opt`はオプション名です。

·

Categories: Plotting

[ < ] | [ > ] |  | [ << ] | [上] | [ >> ] |  |  |  |  | [冒頭] | [目次] | [見出し] | [ ? ]

## 12.2 Plotting Formats

今のところ、Maximaが使う外部のプロットプログラムは2つあります: GnuplotとXmaximaです。 これらのプログラムに対して様々な異なるフォーマットがあります。 それらはオプション `plot_format` で選択することができます。 (Plotting Options節を参照してください。)

プロットフォーマットは以下の通りです:

- gnuplot (Windowsでのデフォルト)

  外部のプログラム gnuplotを起動するのに使われます。 あなたのシステムに gnuplotがインストールされていなければいけません。 すべてのプロットコマンドとデータはファイル `maxout.gnuplot`に保存されます。

- gnuplot_pipes (Windows以外のプラットフォームでのデフォルト)

  このフォーマットは Windowsプラットフォームでは利用できません。 `gnuplot`フォーマットと似ていますが、 データがファイル `maxout.gnuplot_pipes`に保存される一方、 コマンドがパイプを通してgnuplotに送られるところが違います。 gnuplotパイプが関数 `gnuplot_close` で閉じられない限り、 １つの gnuplotプロセスが開き続けて、続きのプロットコマンドは同じプロセスに送られ、 以前のプロットを置き換えます。 このフォーマットを使う時、関数 `gnuplot_replot` は 既にスクリーン上に表示されたプロットを変更するのに使うことができます。

  このフォーマットはスクリーンへプロットするためだけに使います; グラフィックファイルが生成される時はいつでも、フォーマットは自動的に `gnuplot`切り替えられ、グラフィックファイルを生成するのに必要なgnuplotコマンドは `maxout.gnuplot`に保存されます。

- 値: `mgnuplot`

  Mgnuplotは gnuplotのTkベースのラッパーです。 Maximaディストリビューションに含まれます。 Mgnuplotは gnuplotの基本的な GUIを提供しますが、 gnuplotの素のインターフェースより総合的な特長は少ないです。 Mgnuplotは gnuplotと Tckl/Tkを別途インストールする必要があります。

- xmaxima

  Xmaximaは Maxima用 Tcl/Tkグラフィカルインターフェースです。 これもまた、コンソールや他のグラフィカルインターフェースから Maximaを走らせた時、 生成プロットを表示するのに使うことができます。 このフォーマットを使うには xmaximaプログラム―これはMaximaと一緒に配布されます― をインストールする必要があります。 もし Maximaを xmaxima自身から走らせるなら、 このフォーマットを指定すると Maximaと Xmaximaの間の通信に使われているのと同じソケットを通して、 プロット関数にデータとコマンドを送ります。 コンソールや他のインターフェースから使われる時は、 そのファイルの位置の名前を引数としてxmaximaプログラムを起動します。

  以前のバージョンではこのフォーマットは `openmath`と呼ばれていました; その古い名前はまだ `xmaxima`に対する同義語として受け付けられます。

·

Categories: Plotting

[ < ] | [ > ] |  | [ << ] | [上] | [ >> ] |  |  |  |  | [冒頭] | [目次] | [見出し] | [ ? ]

## 12.3 Functions and Variables for Plotting

関数: contour_plot (expr, x_range, y_range, options, …)

  exprの等高線を領域 x_range, y_rangeでプロットします。 他の引数は `plot3d` と同じように扱われます。

  プロットフォーマットが`gnuplot`か `gnuplot_pipes`の時だけ この関数は動作します。 追加パッケージ `implicit_plot`も等高線をプロットするのに使われますが、 それは任意のフォーマットで動作します。 `implicit_plot` も参照してください。

  例:

      (%i1) contour_plot (x^2 + y^2, [x, -4, 4], [y, -4, 4])$

  `plot3d`が受け付ける任意のオプションを足すことができます; 例えば、オプション `legend` に falseの値を入れると凡例を取り除きます。 Gnuplotはデフォルトで3つの高等線を示すように選びます。 レベルの数を増やすにはカスタムの gnuplot前置きを指定する必要があります;

      (%i1) contour_plot (u^3 + v^2, [u, -4, 4], [v, -4, 4],
                    [legend,false],
                    [gnuplot_preamble, "set cntrparam levels 12"])$

  ·

  Categories: Plotting

関数: get_plot_option (keyword, index)

  keywordと名付けられたオプションの、グローバル変数 `plot_options`に保存されている現在のデフォルト値を返します。 indexに1を与えるとキーワード自身を返します; 2を与えるとキーワードに続く一番目のパラメータを返す、という具合です。

  `set_plot_option` や `remove_plot_option` , Plotting Optionの節も参照してください。

システム変数: gnuplot_command

  この変数は、 プロットフォーマットが `gnuplot`の時にgnuplotプログラムを走らせるのに使われるコマンド名を保存します。 デフォルト値は、 Windowsでは "wgunplot"、他のシステムでは "gnuplot"です。 完全なパスが与えられず gnuplotプログラムが見つからないか、違うバージョンを試したいときは、 この変数の値を変えることができます。例えば、

      (%i1) gnuplot_command: "/usr/local/bin/my_gnuplot"$

  ·

  Categories: Plotting

システム変数: gnuplot_file_args

  グラフィックファイルが `gnuplot`で生成されようとする時、 この変数は、ファイル名をgnuplotに渡す方法を指定するのに使われます。 デフォルト値は "~s"です。それはファイル名を直接渡すことを意味します。 この変数の中身は、 gnuplotプログラムに関してオプションを、"~s"の前にオプションを加えて加えることで変更可能です。

  ·

  Categories: Plotting

システム変数: gnuplot_view_args

  この変数は、プロットフォーマットが `gnuplot`の時 gnuplotプログラムに渡す引数をパースするのに使います。 デフォルト値は "-persist ~s"です。 ここで "~s"は gnuplotコマンドが書かれるファイル名(通常 "maxout.gnuplot")に置き換えられます。 オプション `-persist`は ファイルの中のコマンドが実行された後、プロットを表示しているウィンドウを閉じずに gnuplotを終了させます。

  gnuplotに詳しい人たちはこの変数の値を替えたいかもしれません。 例えば、それを以下のように変えることで:

      (%i1) gnuplot_view_args: "~s -"$

  ファイルの中のコマンドが実行された後、gnuplotは閉じません; なので、プロットを含むウィンドウはもちろん、プロットを修正するため他のコマンドを発行できるgnuplot対話シェルも残ります。

  4.6.3より古い gnuplotの Windowsバージョンでは、 "~s -"と "-persist ~s"の振る舞いは反対でした; その名の通り "-persist ~s"はプロットウィンドウと gnuplot対話シェルを残す一方で、 "~s -"は プロットウィンドウを残しながら gnuplotシェルを閉じました。 なので、もし Windowsで古い gnuplotバージョンを使っているなら、 `gnuplot_view_args`の値を調整する必要があるかもしれません。

  ·

  Categories: Plotting

関数: implicit_plot (expr, x_range, y_range)
関数: implicit_plot ([expr_1, ..., expr_n], x_range, y_range)

  １つ以上の式のプロットを陰形式で表示します。 exprはプロットされる式で、 x_rangeは水平軸の範囲、 y_rangeは垂直軸の範囲です。 `implicit_plot`は set_plot_option関数が設定するgnuplotドライバのグローバル設定を考慮します。 オプションはオプション引数として`implicit_plot`関数にも渡されることができます。

  `implicit_plot`は x_rangeとy_rangeで与えられる領域上で符号の変化を辿ることで機能し、 複雑な式では失敗する可能性があります。

  `load(implicit_plot)`はこの関数をロードします。

  例:

      (%i1) load(implicit_plot)$
      (%i2) implicit_plot (x^2 = y^3 - 3*y + 1, [x, -4, 4], [y, -4, 4])$

  ·

  Categories: Plotting ·Share packages ·Package implicit_plot

関数: julia (x, y, ...options...)

  複素数 (x + i y)に関する Julia集合の表現のグラフィックスファイルを生成します。 2つの必須パラメータ xと yは実数でなければいけません。 このプログラムは追加パッケージ `dynamics`の一部ですが、そのパッケージはロードする必要はなく、 juliaが使われる初回に自動的にロードされます。

  グリッドのそれぞれのピクセルは、 その点からシュッパウして原点を中心とした半径2の収束円からはみ出るまでの繰り返しの回数に対応した色が与えられます。 グリッドのピクセルの数は `grid` プロットオプションが制御します(デフォルトは30掛ける30)。 繰り返しの最大数はオプション `iterations` で設定されます。 プログラムは自身のデフォルトパレットを使います: マゼンダ、紫、青、シアン、緑、黄、赤、茶、黒。 しかしコマンドで明示的に `palette` オプションを加えることで変更できます。

  使われるデフォルトの領域は、両方の軸で-2から2までで、 `x`と `y`オプションを使って変えられます。 オプション `yx_ratio` を使うか、オプション `same_xy` をディセーブルするかどちらかをしない限り デフォルトでは2つの軸は同じスケールで表示されます。 他の一般的なプロットオプションも受け入れられます。

  以下の例は、数-0.55 + i0.6に関するJulia集合の領域を表示します。 オプション `color_bar_tics` は Gnuplotが色ボックスを40まで調整するのを抑制するのに使われています。 この場合、最大36回の繰り返しに対応する点は黒ではないです。

      (%i1) julia (-0.55, 0.6, [iterations, 36], [x, -0.3, 0.2], [y, 0.3, 0.9],
            [grid, 400, 400], [color_bar_tics, 0, 6, 36])$

  ·

  Categories: Package dynamics ·Plotting

関数: make_transform ([var1, var2, var3], fx, fy, fz)

  plot3dのオプション `transform_xy` での使用に適した関数を返します。 3変数 var1, var2, var3は3つのダミー変数名です。 それらは plot3dコマンドが与える3変数 (最初2つの独立変数と、そのあとそれら2つの変数に依存する関数)を表します。 3つの関数fx, fy, fzはそれら3変数だけで決まるはずで、 プロットすべき対応する x, y, z座標を与えます。 デフォルトで定義された2つの変換があります; `polar_to_xy` と`spherical_to_xyz` ; それら2つの変換に関するドキュメンテーションを参照してください。

  ·

  Categories: Plotting

関数: mandelbrot (options)

  Mandelbrot集合の表現のグラフィックスファイルを生成します。 このプログラムは追加パッケージ `dynamics`の一部ですが、そのパッケージはロードする必要はなく、 juliaが使われる初回に自動的にロードされます。

  このプログラムは引数なしに呼び出すことができます。その場合、 点毎にデフォルト値の9回の繰り返し、 `grid` プロットオプション(デフォルトは30掛ける30)で設定された寸法のグリッド、 両方の軸で-2から2まで拡張した領域を使います。 オプションは plot2dが受け付けるのと同じものすべてと、加えて繰り返し数を変えるオプション `iterations` です。

  グリッドのそれぞれのピクセルは、 その点からシュッパウして原点を中心とした半径2の収束円からはみ出るまでの繰り返しの回数に対応した色が与えられます。 グリッドのピクセルの数は `grid` プロットオプションが制御します(デフォルトは30掛ける30)。 繰り返しの最大数はオプション `iterations` で設定されます。 プログラムは自身のデフォルトパレットを使います: マゼンダ、紫、青、シアン、緑、黄、赤、茶、黒。 しかしコマンドで明示的に `palette` オプションを加えることで変更できます。 オプション `yx_ratio` を使うか、オプション `same_xy` をディセーブルするかどちらかをしない限り デフォルトでは2つの軸は同じスケールで表示されます。

  例:

      (%i1) mandelbrot ([iterations, 30], [x, -2, 1], [y, -1.2, 1.2], [grid,400,400])$

  ·

  Categories: Package dynamics ·Plotting

システム関数: polar_to_xy

  plot3dの `transform_xy` オプションに対する値として与えることができます。 その効果は plot3dの2つの独立変数をz軸からの距離と方位角(極座標)として通訳し、 それらを xと y座標に変換することです。

  ·

  Categories: Plotting

関数: plot2d (plot, x_range, …, options, …)
関数: plot2d ([plot_1, …, plot_n], …, options, …)
関数: plot2d ([plot_1, …, plot_n], x_range, …, options, …)

  ここで plot, plot_1, …, plot_nは式か関数名、もしくは以下のいずれかの形式のリストです:

  `[discrete, [x1, ..., xn], [y1, ..., yn]]`, `[discrete, [[x1, y1], ..., [xn, ..., yn]]]`, または `[parametric, x_expr, y_expr, t_range]`。

  １つもしくは複数の式を１変数か1パラメータの関数としてプロット表示します。

  `plot2d`は1つもしくは複数のプロットを2次元に表示します。 プロットを定義するのに式や関数名を使う時には、 それらは１変数varだけに依存すべきであり 変数名とその最小値と最大値を提供するためにx_rangeの使用が必須です; x_rangeの構文は以下の通りです:

  `[variable, min, max]`

  プロットを離散形式やパラメトリック形式で定義することもできます。 離散形式は既定の座標で表された点の集合をプロットするのに使われます。 離散プロットはキーワード discreteで始まり、 値についてのリスト1つか2つが続くリストで定義されます。 もし2つのリストが与えられたら、それらは同じ長さを持たなければいけません; 1番目のリストはプロットされる点のx座標として、 2番目のリストはy座標として解釈されます。 もし discreteキーワードの後、リストが1つだけ与えられたら、 それは、リスト上のそれぞれの要素は点のxとy座標に対応する2つの値を持つリストか、 x軸上の連続する整数値(1,2,3,...)にプロットされる数値の数列を受け付けます。

  パラメトリックプロットはキーワード parametricで始まり、 式か関数名2つとパラメータの範囲を持つリストで定義されます。 パラメータの範囲はパラメータ名とその最小値、最大値が続くリストでなければいけません:

  `[param, min, max]`。

  paramが minから maxに増えるにつれ、 式または関数2つで与えられる座標点が描く軌跡をプロットは表示します。

  垂直軸の範囲は以下の形式を持つオプション引数です:

  `[y, min, max]`(キーワード yはいつも垂直軸に使われます)。

  このオプションを使うと、 プロットが到達する値に関係なくオプションの垂直範囲ぴったりをプロットは表示します。 もし垂直範囲を指定しなかったなら、 プロット点のy座標の最小値と最大値に従って垂直範囲が設定されます。

  他のすべてのオプションも キーワードで始まり、1つか複数の値が続くリストでなければいけません。 `plot_options` を参照してください。

  もし複数のプロットがプロットされるなら式のそれぞれを識別するために凡例が書かれます。 その凡例で使われるラベルはオプション `legend` で与えることができます。 もしそのオプションが使われないなら Maximaは式や関数名からラベルを生成します。

  例:

  よくある関数のプロット:

      (%i1) plot2d (sin(x), [x, -%pi, %pi])$

  もし関数の増大が速すぎるなら `y` オプションを使って垂直軸の値を制限する必要があるかもしれません:

      (%i1) plot2d (sec(x), [x, -2, 2], [y, -20, 20])$
      plot2d: some values were clipped.

  プロットボックスがディセーブルの時は軸のためのラベルが生成荒れません。 その場合、`xlabel` と `ylabel` を使って軸の名前を設定する代わりに もっと自由度の高いオプション `label` を使う方がいいです。 オプション `yx_ratio` は、プロットの形のデフォルトである長方形を変更するのに使います; この例ではプロットは平方形を埋めます。

      (%i1) plot2d ( x^2 - 1, [x, -3, 3], [box, false], grid2d, [yx_ratio, 1],
            [axes, solid], [xtics, -2, 4, 2], [ytics, 2, 2, 6],
            [label, ["x", 2.9, -0.3], ["x^2-1", 0.1, 8]], [title, "A parabola"])$

  垂直軸方向の対数プロットの例:

      (%i1) plot2d (exp(3*s), [s, -2, 2], logy)$

  関数を名前でプロット:

      (%i1) F(x) := x^2 $
      (%i2) :lisp (defun |$g| (x) (m* x x x))
      $g
      (%i2) H(x) := if x < 0 then x^4 - 1 else 1 - x^5 $
      (%i3) plot2d ([F, G, H], [u, -1, 1], [y, -1.5, 1.5])$

  パラメトリックに定義されたバタフライカーブのプロット:

      (%i1) r: (exp(cos(t))-2*cos(4*t)-sin(t/12)^5)$
      (%i2) plot2d([parametric, r*sin(t), r*cos(t), [t, -8*%pi, 8*%pi]])$

  パラメトリック表現を使った円を-|x|と合わせてプロット。 円は、もし2つの軸のスケールが同じなら、円のように見えるだけのものです。オプション `same_xy` で指定します。

      (%i1) plot2d([[parametric, cos(t), sin(t), [t,0,2*%pi]], -abs(x)],
               [x, -sqrt(2), sqrt(2)], same_xy)$

  0から9の間の200個の乱数のプロット:

      (%i1) plot2d ([discrete, makelist ( random(10), 200)])$

  x座標, y座標を別々に定義した点の離散集合のプロット:

      (%i1) plot2d ([discrete, makelist(i*%pi, i, 1, 5), [.6, .9, 0.2, 1.3, 1]])$

  次の例では、3つの列を持つテーブルがファイル”data.txt”に保存され、 読み込まれ、2番目、3番目の列は2つの軸上にプロットされます:

      (%i1) with_stdout ("data.txt", for x:0 thru 10 do
                                   print (x, x^2, x^3))$
      (%i2) data: transpose ( read_matrix ("data.txt"))$
      (%i3) plot2d ([discrete, transpose(data)[2], transpose(data)[3]],
        [style,points], [point_type,diamond], [color,red])$

  離散データ点をデータを予測する連続関数と一緒にプロット:

      (%i1) xy: [[10, .6], [20, .9], [30, 1.1], [40, 1.3], [50, 1.4]]$
      (%i2) plot2d([[discrete, xy], 2*%pi*sqrt(l/980)], [l,0,50],
              [style, points, lines], [color, red, blue],
              [point_type, asterisk],
              [legend, "experiment", "theory"],
              [xlabel, "pendulum's length (cm)"],
              [ylabel, "period (s)"])$

  プロットオプションに関する節も参照してください。

  ·

  Categories: Plotting

関数: plot3d (expr, x_range, y_range, …, options, …)
関数: plot3d ([expr_1, expr_2, expr_3], x_range, y_range, …, options, …)

  ２変数関数もしくはパラメトリック形式で定義された１つか複数の表面のプロットを表示します。

  プロットされる関数は式か関数名として指定できます。 違った側面から表面を見るためにマウスを使ってプロットを回転することができます。

  例:

  2変数関数のプロット:

      (%i1) plot3d (u^2 - v^2, [u, -2, 2], [v, -3, 3], [grid, 100, 100],
              [mesh_lines_color,false])$

  無限大に発散する関数を制限するための `z` オプションの使用(この場合、関数はxとy軸上でマイナス無限だい); これは線のみ陰影なしでプロットする仕方も示します。

      (%i1) plot3d ( log ( x^2*y^2 ), [x, -2, 2], [y, -2, 2], [z, -8, 4],
               [palette, false], [color, magenta])$

  zの無限大はいかなる漸近線上にも落ちないグリッドを選ぶことによっても避けることができます; 次の例はパレットの変更の仕方と z変数の値を使って色を関連づけるカラーバーの表示の仕方も示します:

      (%i1) plot3d (log (x^2*y^2), [x, -2, 2], [y, -2, 2],[grid, 29, 29],
             [palette, [gradient, red, orange, yellow, green]], color_bar,
             [xtics, 1], [ytics, 1], [ztics, 4],[color_bar_tics, 4])$

  同一プロットでの2つの表面。 表面の1つに特化した範囲は共通のリストの中に式と範囲を置くことで与えることができます; この例ではそれぞれの表面は全体のプロットの領域と異なる領域で定義されています。

      (%i1) plot3d ([[-3*x - y, [x, -2, 2], [y, -2, 2]],
         4*sin(3*(x^2 + y^2))/(x^2 + y^2), [x, -3, 3], [y, -3, 3]],
         [x, -4, 4], [y, -4, 4])$

  パラメトリックに定義されたKleinの壷のプロット:

      (%i1) expr_1: 5*cos(x)*(cos(x/2)*cos(y) + sin(x/2)*sin(2*y) + 3.0) - 10.0$
      (%i2) expr_2: -5*sin(x)*(cos(x/2)*cos(y) + sin(x/2)*sin(2*y) + 3.0)$
      (%i3) expr_3: 5*(-sin(x/2)*cos(y) + cos(x/2)*sin(2*y))$
      (%i4) plot3d ([expr_1, expr_2, expr_3], [x, -%pi, %pi],
              [y, -%pi, %pi], [grid, 50, 50])$

  球座標から直交座標に変換するのにあらかじめ定義された変換 `spherical_to_xyz`を使った「球調和」関数のプロット。 `spherical_to_xyz` に関するドキュメンテーションを参照してください。

      (%i1) plot3d (sin(2*theta)*cos(phi), [theta, 0, %pi],
              [phi, 0, 2*%pi],
              [transform_xy, spherical_to_xyz], [grid,30,60],
         [legend,false])$

  円筒座標から直交座標に変換するのにあらかじめ定義された変換 `polar_to_xy`を使った球面調和関数のプロット。 `polar_to_xy` に関するドキュメンテーションを参照してください。

      (%i1) plot3d (r^.33*cos(th/3), [r, 0, 1], [th, 0, 6*%pi], [box, false],
         [grid, 12, 80], [transform_xy, polar_to_xy], [legend, false])$

  球座標から直交座標への変換を使っての球のプロット。 同じ比率でスケールされた3軸を得るのにオプション `same_xyz` を使います。 Gnuplotが表面を正確に表示しなくなるので、変換を使う時はメッシュ線を消すのは都合良くありません。

      (%i1) plot3d ( 5, [theta, 0, %pi], [phi, 0, 2*%pi], same_xyz,
        [transform_xy, spherical_to_xyz], [mesh_lines_color,blue],
        [palette,[gradient,"#1b1b4e", "#8c8cf8"]], [legend, false])$

  行列を使った2変数関数の定義。 関数の定義の中のシングルクォートに注意してください。 行列が整数添字を要求する状況に実際に至る時 plot3dが失敗しないためのものです。

      (%i1) M: matrix([1, 2, 3, 4], [1, 2, 3, 2], [1, 2, 3, 4], [1, 2, 3, 3])$
      (%i2) f(x, y) := float('M [round(x), round(y)])$
      (%i3) plot3d (f(x,y), [x, 1, 4], [y, 1, 4], [grid, 3, 3], [legend, false])$

  elevationを零に設定することで表面を地図として見ることができます。 その地図はそれぞれの色は違ったレベルを表現します。

      (%i1) plot3d (cos (-x^2 + y^3/4), [x, -4, 4], [y, -4, 4], [zlabel, ""],
              [mesh_lines_color, false], [elevation, 0], [azimuth, 0],
              color_bar, [grid, 80, 80], [ztics, false], [color_bar_tics, 1])$

  プロットオプションについての節も参照してください。

  ·

  Categories: Plotting

システム変数: plot_options

  このオプションは古いバージョンとの互換性のために残されていますが、使用は勧めません。 グローバルなプロットオプションを設定したり、現在の値を見たり、オプションを削除するには、 `set_plot_option` や `get_plot_option` 、 `remove_plot_option`. を使ってください。

  ·

  Categories: Plotting

Function: remove_plot_option (name)

  オプションのデフォルト値を削除します。 オプション名を与えなければいけません。

  `set_plot_option` と`get_plot_option` , Plotting Optionsの節も参照してください。

  ·

  Categories: Plotting

関数: set_plot_option (option)

  プロットオプションの節にリストされているオプションのすべてを受け付け、 プロットコマンドでの使用のためそれらを保存します。 プロットコマンドそれぞれで設定されるオプションの値は優先順位を持っていますが、 そららのオプションが与えられないなら、この関数で設定されたデフォルト値が使われます。

  `set_plot_option`は引数を評価し、(与えられたオプションを変更した後、)全体のリストを返します。 もし引数なしで呼び出されたら、単に現在のデフォルトオプションのリストを表示します。

  `remove_plot_option` と`get_plot_option` , Plotting Optionsの節も参照してください。

  例:

  `grid` 値の変更。

      (%i1) set_plot_option ([grid, 30, 40]);
      (%o1) [[plot_format, gnuplot_pipes], [grid, 30, 40],
      [run_viewer, true], [axes, true], [nticks, 29], [adapt_depth, 5],
      [color, blue, red, green, magenta, black, cyan],
      [point_type, bullet, box, triangle, plus, times, asterisk],
      [palette, [gradient, green, cyan, blue, violet],
      [gradient, magenta, violet, blue, cyan, green, yellow, orange,
      red, brown, black]], [gnuplot_preamble, ], [gnuplot_term, default]]

  ·

  Categories: Plotting

システム関数: spherical_to_xyz

  `plot3d` の `transform_xy` オプションの値として与えることができます。 その効果は `plot3d`での2つの独立変数と関数を点の球座標 (1番目はz軸に対する角度、次にxy射影のx軸に対する角度、最後に原点からの距離) として解釈し、それらをx,y,z座標に変換することです。

  ·

  Categories: Plotting

[ < ] | [ > ] |  | [ << ] | [上] | [ >> ] |  |  |  |  | [冒頭] | [目次] | [見出し] | [ ? ]

## 12.4 Plotting Options

すべてのオプションは、この節のキーワードの1つで始まり1つ以上の値が続くリストで構成されます。 以下のリストで指摘されるように、オプションのいくつかは違うプロットコマンドで違う効果をを持ちます。 あり得る値としてtrueかfalseを受け付けるオプションは、単にそれらの名前を書くことでtrueを設定できます。 例えば、オプションとしてlogxとタイプすることは[logx, true]と書くことと等価です。

プロットオプション: adapt_depth [adapt_depth, integer]

  デフォルト値: `5`

  適応プロットルーチンで使われる分割の最大数です。

  ·

  Categories: Plotting

プロットオプション: axes [axes, symbol]

  デフォルト値: `true`

  ここで symbolは `true`, `false`, `x`, `y`, `solid`のいずれかです。 もし `false`なら軸は表示されません; もし `x`か `y`に等しいならxかy軸のみが表示され、 `true`に等しいなら両方の軸が表示され、 `solid`は2つの軸を、デフォルトの破線ではなく実線で表示します。 このオプションは 3次元プロットでは効果も持ちません。

  ·

  Categories: Plotting

プロットオプション: azimuth [azimuth, number]

  デフォルト値: `30`

  plot3dプロットは、 plot2dと同じように水平軸と垂直軸を表す x軸と y軸と スクリーンから向かって来る z軸をスタート地点に考えることができます。 その後、z軸を x軸の回りに `elevation` に等しい角度だけ回転し、 さらに 新しい xy平面を新しい z軸の回りに角度 `azimuth`だけ回転します。 このオプションは azimuthに関する値を単位、度で設定します。

  `elevation` も参照してください。

  ·

  Categories: Plotting

プロットオプション: box [box, symbol]

  デフォルト値: `true`

  もし `true`に設定されるなら境界枠がプロットに表示されます; もし `false`に設定されるなら枠は表示されません。

  ·

  Categories: Plotting

プロットオプション: color [color, color_1, …, color_n]

  デフォルト値: `blue`, `red`, `green`, `magenta`, `black`, `cyan`

  2dプロットでは、これは様々な曲線の色を定義します。 `plot3d` では、パレットが使われないとき表面のメッシュ線の色を定義します。

  もし色よりも曲線や表面が多いなら色は順に繰り返されます。 有効な色は `red`, `green`, `blue`, `magenta`, `cyan`, `yellow`, `orange`, `violet`, `brown`, `gray`, `black`, `white`か、文字#で始まり6桁の16進数数字が続く文字列です; 2つは赤成分、2つは緑成分、2つは青成分です。 もし未知の色の名前が与えられたら黒が代わりに使われます。

  ·

  Categories: Plotting

プロットオプション: color_bar [color_bar, symbol]

  デフォルト値: plot3dでは`false`、mandelbrotやjuliaでは `true`

  ここで symbolは `true`か `false` です。 If もし `true`なら、 `plot3d` か、`mandelbrot` , `julia` は異なる値を表現するのにパレットを使い、 色と値の間の対応を示すボックスが右に表示されます。

  ·

  Categories: Plotting

プロットオプション: color_bar_tics [color_bar_tics, x1, x2, x3]

  カラーバー内でマークと数字を置く場所の値を定義します。 マークを置く場所に関して一番目の数字は初期値、二番目は増分、三番目は最終値です。 二番目と三番目の数字は省略できます。 ただ1つの数字だけ与えたときは、それは自動的に選ばれる初期値からの増分として使われます。

  ·

  Categories: Plotting

プロットオプション: elevation [elevation, number]

  デフォルト値: `60`

  plot3dプロットは、 plot2dと同じように水平軸と垂直軸を表す x軸と y軸と スクリーンから向かって来る z軸をスタート地点に考えることができます。 その後、z軸を x軸の回りに `elevation` に等しい角度だけ回転し、 さらに xy平面を新しい z軸の回りに角度 `azimuth` だけ回転します。 このオプションは azimuthの値を度単位で設定します。

  `azimuth` も参照してください。

  ·

  Categories: Plotting

プロットオプション: grid [grid, integer, integer]

  デフォルト値: `30`, `30`

  3次元プロットや `julia` , `mandelbrot` プログラムのために x方向、y方向で使われるグリッド点の数を設定します。

  ·

  Categories: Plotting

プロットオプション: grid2d [grid, value]

  でフォルト値: `false`

  xy平面上に線のグリッドを表示します。 グリッド線が置かれる点は、xとy軸にマークされた目盛と同じ点です。 目盛は `xtics` と `ytics` オプションで制御できます。

  ·

  Categories: Plotting

プロットオプション: iterations [grid, value]

  デフォルト値: `9`

  プログラム mandelbrotと juliaが行う繰り返し回数。

  ·

  Categories: Plotting

プロットオプション: label [label, [string, x, y], …]

  それぞれのラベルの後に示される x, y座標を持つ点にラベルを書きます。

  ·

  Categories: Plotting

プロットオプション: legend [legend, string_1, …, string_n]
プロットオプション: legend [legend, false]

  複数のプロットを表示する時プロットのラベルを指定します。 もし与えたラベルの数より多くの式があるならラベルは繰り返されます。 もし値 `false`を与えたなら、凡例は表示されません。 デフォルトでは式や関数の名前が使われます。また、点の離散集合に関しては単語 discrete1, discrete2, …が使われます。

  ·

  Categories: Plotting

プロットオプション: logx [logx, value]

  水平軸を対数的にスケールするようにします。 trueか falseです。

  ·

  Categories: Plotting

プロットオプション: logy [logy, value]

  垂直軸を対数的にスケールするようにします。 trueか falseです。

  ·

  Categories: Plotting

プロットオプション: mesh_lines_color [mesh_lines_color, color]

  デフォルト値: `black`

  パレットが使われる時 plot3dがメッシュ線を描くのに使う色を設定します。 オプション `color` と同じ色を受け付けます。 (`color` で許される色のリストを参照してください。) 値 `false`を与えてメッシュ線を完全に消すこともできます。

  ·

  Categories: Plotting

プロットオプション: nticks [nticks, integer]

  デフォルト値: `29`

  `plot2d` で関数をプロットする時、 関数をプロットするための適応プロットルーチンによって使われる点の数の初期値を与えます。 `plot3d` でパラメトリック関数をプロットする時、 プロットで表示される点の数を設定します。

  ·

  Categories: Plotting

プロットオプション: palette [palette, [palette_1], ..., [palette_n]]
プロットオプション: palette [palette, false]

  1つのパレットか複数のパレットのリストで構成されます。 パレットそれぞれはキーワードに複数の値が続くリストです。 もしキーワードが gradientなら、有効な色のリストを続けなければいけません。

  もしキーワードが hueか saturation、valueなら、4つの数字を続けなければいけません。 最初の3つの数は0と1の間でなければならず、 zの最小値に割り当てられる基本色の色調と飽和、値を定義します。 キーワードは3つの属性(色調、飽和、値)のいずれかがzの値に従っての増えることを指定します。 その最後の数は1よりも大きいこともマイナスでもありえます; 変更された属性の対応する値は法1で丸められます。

  gnuplotはリストの中の最初のパレットだけを使います; xmaximaは、複数の表面を一緒にプロットする時リストの中のパレットを順に使います; パレットの数が尽きたらそれらは順に繰り返されます。

  メッシュ線の色はオプション `mesh_lines_color` で与えられます。 もし `palette`が値 `false`を与えられたら、 表面は陰影されず曲線のメッシュだけで表されます。 その場合、線の色はオプション `color` で決定されます。

  ·

  Categories: Plotting

プロットオプション: plot_format [plot_format, format]

  デフォルト値: Windowsシステムでは`gnuplot`, 他のシステムでは`gnuplot_pipes`

  ここでformatは以下のいずれかです; gnuplot, xmaxima, mgnuplot, gnuplot_pipes.

  プロットで使われるフォーマットを設定します。

  ·

  Categories: Plotting

プロットオプション: plot_realpart [plot_real_part, symbol]

  デフォルト値: `false`

  `true`に設定される時、 プロットされる関数は実数値がプロットされる複素関数と見なされます; これは `realpart(function)`をプロットすることと同値です。 もし `false`に設定されたら、 関数が実数値を与えない時には何も表示されません。 例えば、 `x`が負の時、 `log(x)`は実数値が`log(abs(x))`に等しい複素数値を与えます; もし `plot_realpart`が `true`だったなら `log(-5)`は `log(5)`としてプロットされますが、 もし `plot_realpart`が `false`だったなら 何もプロットされません。

  ·

  Categories: Plotting

プロットオプション: point_type [point_type, type_1, …, type_n]

  gnuplotでは、 スタイル“points”か“linespoints”でプロットされた点の集合それぞれは このリストから取られたオブジェクトを使って順に表されます。 もしこのリスト内のオブジェクト以上に点の集合があるなら、 それらは順に繰り返されます。 使うことができる可能なオブジェクト: `bullet`, `circle`, `plus`, `times`, `asterisk`, `box`, `square`, `triangle`, `delta`, `wedge`, `nabla`, `diamond`, `lozenge`

  ·

  Categories: Plotting

プロットオプション: pdf_file [pdf_file, file_name]

  このオプションは、プロットをスクリーンに表示する代わりに file_nameという名前の PDFファイルに保存します。 file_nameが文字“/”を含まない限り、デフォルトでは、そのファイルは変数 `maxima_tempdir` で定義されたディレクトリに生成されます; `maxima_tempdir` の値を変えて違うディレクトリにファイルを保存できます。 オプション `gnuplot_pdf_term_command` も与えられた時は、それを使って Gnuplotの PDF端末をセットアップします; そうでなければ、Gnuplotの pdfcairo端末は EPSオプション、幅 3の実線、17.2 cm掛ける12.9 cmのプロットサイズ、18ポイントのフォントを使います。

  ·

  Categories: Plotting

プロットオプション: png_file [png_file, file_name]

  このオプションは、プロットをスクリーンに表示する代わりに file_nameという名前の PNGグラフィックファイルに保存します。 file_nameが文字“/”を含まない限り、デフォルトでは、そのファイルは変数 `maxima_tempdir` で定義されたディレクトリに生成されます; `maxima_tempdir` の値を変えて違うディレクトリにファイルを保存できます。 オプション `gnuplot_png_term_command` も与えられた時は、それを使って Gnuplotの PNG端末をセットアップします; そうでなければ、Gnuplotの pngcairo端末は 12ポイントのフォントを使います。

  ·

  Categories: Plotting

プロットオプション: ps_file [ps_file, file_name]

  このオプションは、プロットをスクリーンに表示する代わりに file_nameという名前のポストスクリプトファイルに保存します。 file_nameが文字“/”を含まない限り、デフォルトでは、そのファイルは変数 `maxima_tempdir` で定義されたディレクトリに生成されます; `maxima_tempdir` の値を変えて違うディレクトリにファイルを保存できます。 オプション `gnuplot_ps_term_command` も与えられた時は、それを使ってGnuplotのPostscript端末をセットアップします; そうでなければ、GnuplotのPostscript端末は EPSオプション、幅2の実線、16.4 cm掛ける12.3 cmのプロットサイズ、24ポイントのフォントを使います。

  ·

  Categories: Plotting

プロットオプション: run_viewer [run_viewer, symbol]

  このオプションは、プロットフォーマットが `gnuplot`で端末が `default`の時か、 Gnuplot端末が `dumb`(`gnuplot_term` を参照してください)に設定される時、使用されるだけです。 trueかfalseを取ります。

  もし端末が `default`なら、ファイル `maxout.gnuplot` (もしくは`gnuplot_out_file` )で指定された他の名前)が プロットを生成するのに必要なgnuplotコマンドで作成されます。 オプション `run_viewer`はこれらのコマンドを実行しプロットを表示するために Gnuplotが起動されるかどうかを制御します。

  もし端末が `default`なら、gnuplotが起動し、 `maxout.gnuplot`内のコマンドを実行し、 別のファイル `maxplot.txt`(もしくは`gnuplot_out_file` で指定された別の名前)を生成します。 オプション `run_viewer`は プロットのASCII表現であるそのファイルをMaximaかXmaximaコンソールで表示するかどうかを制御します。

  このオプションのデフォルト値は trueで、プロットをコンソールか別のグラフィックウィンドウで表示されるようにします。

  ·

  Categories: Plotting

プロットオプション: same_xy [same_xy , value]

  trueか falseを取ります。 2dでも 3dプロットでも、もし trueなら xとy軸で使われるスケールが同じになります。 `yx_ratio` も参照してください。

  ·

  Categories: Plotting

プロットオプション: same_xyz [same_xyz , value]

  trueか falseを取ります。 もし trueなら 3dプロットの3軸で使われるスケールが同じになります。

  ·

  Categories: Plotting

プロットオプション: style [style, type_1, …, type1_n]
プロットオプション: style [style, [style_1], …, [style_n]]

  様々な関数やデータ一式のために2dプロットで使われるスタイル。 単語 styleの後には１つ以上のスタイルが続きます。 もし与えられたスタイルよりも多くの関数やデータ集合があったらスタイルは繰り返されます。 それぞれのスタイルは、実線のためにはlines、孤立点のためにはpoints、 線分と孤立点のためにはlinespoints、点線のためにはdotsを取り得ます。 Gnuplotでは impulsesスタイルも使えます。

  スタイルそれぞれはいくつかの追加のパラメータとリストの中に入れることができます。 linesは１つか２つの数を取ります: 線の太さと、色を指定する整数。 デフォルトの色コードは、1: 青, 2: 赤, 3: マゼンタ, 4: オレンジ, 5: ブラウン, 6: ライム, 7: アクア、です。 もしX11ではない端末でGnuplotを使うならこれらの色は違っているかもしれません; 例えば、もしオプション [gnuplot_term, ps]を使うなら 色インデックス 4はオレンジではなく黒に対応します。

  pointsは１つか２つか３つのパラメータを取ります; 最初のパラメータは点の半径、２番目のパラメータは同じ色を選択する （linesで使われるコードと同じ）整数、 ３番目のパラメータは現在Gnuplotでだけ使われており、 点の代わりにいくつかのオブジェクトに対応します。 オブジェクトのデフォルト値は、1: 黒丸, 2: 白丸, 3: 十字, 4: ×, 5: 米印, 6: 黒四角, 7: 白四角, 8: 黒三角, 9: 白三角, 10: 黒逆三角, 11: 白逆三角, 12: 黒菱形, 13: 白菱形 です。

  linesdotsは４つまでのパラメータを取ります; 線の太さ、点の半径、色、点を置き換えるオブジェクトのタイプ。

  `color` と `point_type` も参照してください。

  ·

  Categories: Plotting

プロットオプション: svg_file [svg_file, file_name]

  このオプションは、プロットをスクリーンに表示する代わりに file_nameという名前のポストスクリプトファイルに保存します。 file_nameが文字“/”を含まない限り、デフォルトでは、そのファイルは変数 `maxima_tempdir` で定義されたディレクトリに生成されます; `maxima_tempdir` の値を変えて違うディレクトリにファイルを保存できます。 オプション `gnuplot_svg_term_command` も与えられた時は、それを使ってGnuplotの SVG端末をセットアップします; そうでなければ、Gnuplotの svg端末は 14ポイントのフォントを使います。

  ·

  Categories: Plotting

プロットオプション: t [t, min, max]

  パラメトリックプロットのデフォルトの範囲。

  ·

  Categories: Plotting

プロットオプション: title [title, text]

  プロットの頭に書かれるタイトルを定義します。

  ·

  Categories: Plotting

プロットオプション: transform_xy [transform_xy, symbol]

  デフォルト値: `false`

  ここで、symbolは `false`か関数 `transform_xy`を使って得られる結果をです。 もし `false`と違うなら plot3dで3座標を変換するのに使われます。

  `make_transform` , `polar_to_xy` , `spherical_to_xyz` を参照してください。

  ·

  Categories: Plotting

プロットオプション: x [x, min, max]

  `plot2d` コマンドの最初の(または `plot3d` の最初の二つのどちらかの) オプションとして使われる時、 1番目の独立変数が xであることを示しその範囲を設定します。 最初のオプションの後(またはplot3dでは2番目のオプションの後)、 プロット内で示される有効な水平領域を定義するために再び使うことができます。

  ·

  Categories: Plotting

プロットオプション: xlabel [xlabel, string]

  1番目の軸をラベルするstringを指定します; もしこのオプションが使われないなら、 `plot2d` か `implicit_plot` で関数をプロットする時、 そのラベルは独立変数の名前です。 `plot3d` で表面を、もしくは`contour_plot` で等高線をプロットする時、 そのラベルは1番目の変数の名前です。 パラメトリックプロットの場合、1番目の式です。 `set_plot_option` では使うことはできません。

  ·

  Categories: Plotting

プロットオプション: xtics [xtics, x1, x2, x3]

  x軸上でマークと数が置かれる場所の値を定義します。 マークが置かれる場所に関して、一番目の数が初期値、二番目が増分、三番目が最終値です。 二番目と三番目の数は省略できます。 1つだけ数が与えられた時は、自動的に選ばれる初期値からの増分として使われます。

  ·

  Categories: Plotting

プロットオプション: xy_scale [xy_scale, sx, sy]

  2dプロットでは、ウィンドウの総サイズとプロットに使われるサイズの比を定義します。 引数として与えられた2つの数は xと y軸でのスケール因子です。

  ·

  Categories: Plotting

プロットオプション: y [y, min, max]

  `plot3d` での最初の2つのオプションの1つとして使われる時、 独立変数の1つが yであることを示しその範囲を設定します。 そうでないならプロットで示される2番目の変数の有効領域を定義します。

  ·

  Categories: Plotting

プロットオプション: ylabel [ylabel, string]

  二番目の軸をラベルするstringを指定します; もしこのオプションが使われないなら、 `plot2d` や `implicit_plot` で関数をプロットする時 そのラベルは、”y”となり、 `plot3d` で表面をプロットする時や `contour_plot` で等高線をプロットする時 二番目の変数名となり、 パラメトリックプロットの場合には二番目の式になります。 `set_plot_option` では使うことはできません。

  ·

  Categories: Plotting

プロットオプション: ytics [ytics, y1, y2, y3]

  y軸上でマークと数が置かれる場所の値を定義します。 マークが置かれる場所に関して、一番目の数が初期値、二番目が増分、三番目が最終値です。 二番目と三番目の数は省略できます。 1つだけ数が与えられた時は、自動的に選ばれる初期値からの増分として使われます。

  ·

  Categories: Plotting

プロットオプション: yx_ratio [yx_ratio, r]

  2dプロットでは、プロットを作るのに使われる長方形の垂直側と水平側の間の比。 `same_xy` も参照してください。

  ·

  Categories: Plotting

プロットオプション: z [z, min, max]

  プロットで示されるzの値の有効範囲を設定するために `plot3d` で使われます。

  ·

  Categories: Plotting

プロットオプション: zlabel [zlabel, string]

  `plot3d` を使う時、第三軸をラベルする stringを指定します。 もしこのオプションが使われないなら、 そのラベルは表面をプロットする時は“z”となり、 パラメトリックプロットの場合には三番目の式になります。 `set_plot_option` では使うことはできません。 また、`plot2d` , `implicit_plot` では無視されます。

  ·

  Categories: Plotting

プロットオプション: zmin [zmin, z]

  3dプロットでの、プロットボックスの底のzの値。

  ·

  Categories: Plotting

[ < ] | [ > ] |  | [ << ] | [上] | [ >> ] |  |  |  |  | [冒頭] | [目次] | [見出し] | [ ? ]

## 12.5 Gnuplot Options

gnuplotに特化したプロットオプションがいくつかあります。 これらのオプションのいくつかは gnuplotコマンドそのものであり文字列として指定されます。 詳細はgnuplotドキュメンテーションを参照してください。 ほとんどの場合、これらのオプションは より一般的な上記のオプションの１つで置き換えることができます; これらの場合、より一般的な形式を使うことをお勧めします。

プロットオプション: gnuplot_term [gnuplot_term, terminal_name]

  gnuplot用の出力端末タイプを設定します。 引数 terminal_nameは文字列か以下の3の特殊シンボルです。

  - default (デフォルト値)

    Gnuplot出力が別のグラフィカルなウィンドウに表示されます。 使われる gnuplot端末はオプション `gnuplot_default_term_command` の値で指定されます。

  - dumb

    Gnuplot出力がグラフィックスの "ASCIIアート"近似でファイル `maxout.gnuplot`に保存されます。 もしオプション `gnuplot_out_file` が filenameに設定されたなら、 プロットはデフォルト `maxout.gnuplot`の代わりにそこに保存されます。

  - ps

    Gnuplotがポストスクリプトページ記述言語でコマンドを生成します。 もしオプション `gnuplot_out_file` が filenameに設定されているなら、 gnuplotは filenameにポストスクリプトコマンドを書きます。 そうでなけいなら `maxplot.ps`ファイルとして保存します。 この端末の設定はオプション `gnuplot_dumb_term_command` の値で与えられます。

  - 任意の有効な gnuplotターム仕様を示す文字列

    Gnuplotは、png, jpeg, svgのような多くの他のグラフィカルフォーマットで出力を 生成することができます。 これらのフォーマットを使うには、 オプション `gnuplot_term`に 任意のサポートされた gnuplot端末名(シンボル)を設定します。 任意の有効なオプションを伴う gnuplot端末フル仕様(文字列)さえ設定可能です。 例えば、`[gnuplot_term, png]`はPNG (Portable Network Graphics)形式で 出力を生成しますし、 `[gnuplot_term, "png size 1000,1000"]`は 1000 x 1000ピクセルサイズのPNGを生成します。

    もしオプション `gnuplot_out_file` が filenameに設定されたら、 gnuplotは filenameに出力を書き込みます。 そうでないなら `maxplot.term`ファイルに書き込みます。 ここで termはgnuplot端末名です。

  ·

  Categories: Plotting

プロットオプション: gnuplot_out_file [gnuplot_out_file, file_name]

  端末が `default`に設定されている時、 gnuplotがインタープレトするコマンドを含むファイルのデフォルト名を置き換えるのに使われます。 また、端末が `default`と違う時、 gnuplotが生成するグラフィックファイルのデフォルト名を置き換えるのに使われます。 もし1以上のスラッシュ“/”を含むなら、 ファイルの名前はそのままになります; プロットコマンドが生成するファイルの完全な名前はいつも それらのコマンドの出力として送られるので、 コマンドがセミコロンで終了しているならそれらを見ることができます。

  `gnuplot_term` オプションと関連して使われる時、 Gnuplotがサポートするグラフィックフォーマットの１つで ファイルにプロットを保存するのに使われます。 PNGや, PDF, ポストスクリプト, SVGを生成するには、 オプション `png_file` , `pdf_file` , `ps_file` , `svg_file` を使うのがより簡単です。

  ·

  Categories: Plotting

プロットオプション: gnuplot_pm3d [gnuplot_pm3d, value]

  `false`の値ではPM3Dモードの使用をディレーブルするのに使われます。 PM3Dモードはデフォルトで使用可能です。

  ·

  Categories: Plotting

プロットオプション: gnuplot_preamble [gnuplot_preamble, string]

  このオプションは Gnuplotに送られるどんな他のコマンドの前に gnuplotコマンドを挿入します。 有効な gnuplotコマンドはどんなものでも使うことができます。 複数のコマンドはセミコロンで分離されなければいけません。 `gnuplot_postamble` も参照してください。

  ·

  Categories: Plotting

プロットオプション: gnuplot_postamble [gnuplot_postamble, string]

  このオプションは Gnuplotに送られる他のコマンドの後でプロットコマンドが送られる直前に gnuplotコマンドを挿入します。 有効な gnuplotコマンドはどんなものでも使うことができます。 複数のコマンドはセミコロンで分離されなければいけません。 `gnuplot_preamble` も参照してください。

  ·

  Categories: Plotting

プロットオプション: gnuplot_default_term_command

  [gnuplot_default_term_command, command]

  デフォルト端末として端末タイプを設定するgnuplotコマンド。 もしこのオプションが設定されていなければ、使われるコマンドは以下の通り: `"set term wxt size 640,480 font \",12\"; set term pop"`

  ·

  Categories: Plotting

プロットオプション: gnuplot_dumb_term_command

  [gnuplot_dumb_term_command, command]

  ダム端末として端末タイプを設定するgnuplotコマンド。 もしこのオプションが設定されていなければ、使われるコマンドは以下の通り: `"set term dumb 79 22"` これは79文字掛ける22文字のテキスト出力を生成します。

  ·

  Categories: Plotting

プロットオプション: gnuplot_pdf_term_command [gnuplot_pdf_term_command, command]

  PDF端末として端末タイプを設定するgnuplotコマンド。 もしこのオプションが設定されていなければ、使われるコマンドは以下の通り: `"set term pdfcairo color solid lw 3 size 17.2 cm, 12.9 cm font \",18\""` 更に知るにはgnuplotドキュメントを参照してください。

  ·

  Categories: Plotting

プロットオプション: gnuplot_png_term_command [gnuplot_png_term_command, command]

  PNG端末として端末タイプを設定するgnuplotコマンド。 もしこのオプションが設定されていなければ、使われるコマンドは以下の通り: `"set term pngcairo font \",12\""` 更に知るにはgnuplotドキュメントを参照してください。

  ·

  Categories: Plotting

プロットオプション: gnuplot_ps_term_command [gnuplot_ps_term_command, command]

  ポストスクリプト端末として端末タイプを設定するgnuplotコマンド。 もしこのオプションが設定されていなければ、使われるコマンドは以下の通り: `"set term postscript eps color solid lw 2 size 16.4 cm, 12.3 cm font \",24\""` 更に知るには `set term postscript`に関する gnuplotドキュメントを参照してください。

  ·

  Categories: Plotting

プロットオプション: gnuplot_svg_term_command [gnuplot_svg_term_command, command]

  SVG端末として端末タイプを設定するgnuplotコマンド。 もしこのオプションが設定されていなければ、使われるコマンドは以下の通り: `"set term svg font \",14\""`. 更に知るには gnuplotドキュメントを参照してください。

  ·

  Categories: Plotting

プロットオプション: gnuplot_curve_titles

  これは上記で記載した `legend` で置き換えられた古いオプションです。

  ·

  Categories: Plotting

プロットオプション: gnuplot_curve_styles

  これは上記で記載した `style` で置き換えられた古いオプションです。

  ·

  Categories: Plotting

プロットオプション: gnuplot_default_term_command

  デフォルト端末の端末タイプを設定する gnuplotコマンド。 デフォルト値は `"set term pop"`です。

  ·

  Categories: Plotting

プロットオプション: gnuplot_dumb_term_command

  ダム端末の端末タイプを設定するgnuplotコマンド。 デフォルト値は `"set term dumb 79 22"`です。 これは79文字 x 22文字のテキスト出力を生成します。

  ·

  Categories: Plotting

プロットオプション: gnuplot_ps_term_command

  ポストスクリプト端末の端末タイプを設定するgnuplotコマンド。 デフォルト値は `"set size 1.5, 1.5; set term postscript eps enhanced color solid 24"`, です。 これはサイズをgnuplotのデフォルトの1.5倍に設定し、フォントサイズを24に設定などします。 `set term postscript`の詳細については gnuplotドキュメンテーションを参照してください。

  ·

  Categories: Plotting

[ < ] | [ > ] |  | [ << ] | [上] | [ >> ] |  |  |  |  | [冒頭] | [目次] | [見出し] | [ ? ]

## 12.6 Gnuplot_pipes Format Functions

関数: gnuplot_start ()

  `gnuplot_pipes`フォーマットでのプロットのため使われる gnuplotへのパイプを開きます。 プロットの前に手動でパイプを開く必要はありません。

  ·

  Categories: Plotting

関数: gnuplot_close ()

  `gnuplot_pipes`フォーマットで使われた gnuplotへのパイプを閉じます。

  ·

  Categories: Plotting

関数: gnuplot_restart ()

  `gnuplot_pipes`フォーマットで使われた gnuplotへのパイプを閉じて新しいパイプを開きます。

  ·

  Categories: Plotting

関数: gnuplot_replot ()
関数: gnuplot_replot (s)

  gnuplotウィンドウを更新します。 もし `gnuplot_replot`が文字列 sの中の gnuplotコマンドを引数としてコールされたなら ウィンドウが再プロットされる前に `s`を gnuplotに送ります。

  ·

  Categories: Plotting

関数: gnuplot_reset ()

  `gnuplot_pipes`フォーマットと一緒に使われる gnuplotの状態をリセットします。 gnuplotウィンドウを更新するには `gnuplot_reset`の後に `gnuplot_replot` をコールください。

  ·

  Categories: Plotting

[ << ] | [ >> ] |  |  |  |  |  | [冒頭] | [目次] | [見出し] | [ ? ]

この文書は市川 雄二によって2014年4月月20日にtexi2html 1.82を用いて生成されました。