# Scripts

Related topics:

- Using the Program: How to use AutoHotkey, in general.
- Concepts and Conventions: General explanation of various concepts utilised by AutoHotkey.
- Scripting Language: Specific details about syntax (how to write scripts).

## Table of Contents

- Introduction
- The Top of the Script (the Auto-execute Section): This portion executes automatically when the script starts.
- Splitting a Long Line into a Series of Shorter Ones: This can improve a script's readability and maintainability.
- Convert a Script to an EXE (Ahk2Exe): Convert a .ahk script into a .exe file that can run on any PC.
- Passing Command Line Parameters to a Script: The variables %1%, %2%, etc. contain the incoming parameters.
- Script File Codepage: Using non-ASCII characters safely in scripts.
- Debugging a Script: How to find the flaws in a misbehaving script.

## Introduction

Each script is a plain text file containing lines to be executed by the program (AutoHotkey.exe). A script may also contain hotkeys and hotstrings, or even consist entirely of them. However, in the absence of hotkeys and hotstrings, a script will perform its commands sequentially from top to bottom the moment it is launched.

The program loads the script into memory line by line, and each line may be up to 16,383 characters long. During loading, the script is optimized and validated. Any syntax errors will be displayed, and they must be corrected before the script can run.

## The Top of the Script (the Auto-execute Section)

After the script has been loaded, it begins executing at the top line, continuing until a Return, Exit, hotkey/hotstring label, or the physical end of the script is encountered (whichever comes first). This top portion of the script is referred to as the auto-execute section.

Note: While the script's first hotkey/hotstring label has the same effect as return, other hotkeys and labels do not.

A script that is not persistent and that lacks hotkeys, hotstrings, OnMessage(), and GUI will terminate after the auto-execute section has completed. Otherwise, it will stay running in an idle state, responding to events such as hotkeys, hotstrings, GUI events, custom menu items, and timers.

Every thread launched by a hotkey, hotstring, menu item, GUI event, or timer starts off fresh with the default values for the following attributes as set in the auto-execute section. If unset, the standard defaults will apply (as documented on each of the following pages): AutoTrim, CoordMode, Critical, DetectHiddenText, DetectHiddenWindows, FileEncoding, ListLines, SendLevel, SendMode, SetBatchLines, SetControlDelay, SetDefaultMouseSpeed, SetFormat, SetKeyDelay, SetMouseDelay, SetRegView, SetStoreCapsLockMode, SetTitleMatchMode, SetWinDelay, StringCaseSense, and Thread.

If the auto-execute section takes a long time to complete (or never completes), the default values for the above settings will be put into effect after 100 milliseconds. When the auto-execute section finally completes (if ever), the defaults are updated again to be those that were in effect at the end of the auto-execute section. Thus, it's usually best to make any desired changes to the defaults at the top of scripts that contain hotkeys, hotstrings, timers, or custom menu items. Also note that each thread retains its own collection of the above settings. Changes made to those settings will not affect other threads.

## Splitting a Long Line into a Series of Shorter Ones

Long lines can be divided up into a collection of smaller ones to improve readability and maintainability. This does not reduce the script's execution speed because such lines are merged in memory the moment the script launches.

Method #1: A line that starts with "and", "or", ||, &&, a comma, or a period is automatically merged with the line directly above it (in v1.0.46+, the same is true for all other expression operators except ++ and --). In the following example, the second line is appended to the first because it begins with a comma:

    FileAppend, This is the text to append.`n   ; A comment is allowed here.
        , %A_ProgramFiles%\SomeApplication\LogFile.txt  ; Comment.

Similarly, the following lines would get merged into a single line because the last two start with "and" or "or":

    if (Color = "Red" or Color = "Green"  or Color = "Blue"   ; Comment.
        or Color = "Black" or Color = "Gray" or Color = "White")   ; Comment.
        and ProductIsAvailableInColor(Product, Color)   ; Comment.

The ternary operator is also a good candidate:

    ProductIsAvailable := (Color = "Red")
        ? false  ; We don't have any red products, so don't bother calling the function.
        : ProductIsAvailableInColor(Product, Color)

Although the indentation used in the examples above is optional, it might improve clarity by indicating which lines belong to ones above them. Also, it is not necessary to include extra spaces for lines starting with the words "AND" and "OR"; the program does this automatically. Finally, blank lines or comments may be added between or at the end of any of the lines in the above examples.

Method #2: This method should be used to merge a large number of lines or when the lines are not suitable for Method #1. Although this method is especially useful for auto-replace hotstrings, it can also be used with any command or expression. For example:

    ; EXAMPLE #1:
    Var =
    (
    Line 1 of the text.
    Line 2 of the text. By default, a linefeed (`n) is present between lines.
    )

    ; EXAMPLE #2:
    FileAppend,  ; The comma is required in this case.
    (
    A line of text.
    By default, the hard carriage return (Enter) between the previous line and this one will be written to the file as a linefeed (`n).
        By default, the tab to the left of this line will also be written to the file (the same is true for spaces).
    By default, variable references such as %Var% are resolved to the variable's contents.
    ), C:\My File.txt

In the examples above, a series of lines is bounded at the top and bottom by a pair of parentheses. This is known as a continuation section. Notice that the bottom line contains FileAppend's last parameter after the closing parenthesis. This practice is optional; it is done in cases like this so that the comma will be seen as a parameter-delimiter rather than a literal comma.

The default behavior of a continuation section can be overridden by including one or more of the following options to the right of the section's opening parenthesis. If more than one option is present, separate each one from the previous with a space. For example: `( LTrim Join| %`.

Join: Specifies how lines should be connected together. If this option is omitted, each line except the last will be followed by a linefeed character (`n). If the word Join is specified by itself, lines are connected directly to each other without any characters in between. Otherwise, the word Join should be followed immediately by as many as 15 characters. For example, `Join`s` would insert a space after each line except the last ("`s" indicates a literal space -- it is a special escape sequence recognized only by Join). Another example is `Join`r`n`, which inserts CR+LF between lines. Similarly, `Join|` inserts a pipe between lines. To have the final line in the section also ended by a join-string, include a blank line immediately above the section's closing parenthesis.

Known limitation: If the Join string ends with a colon, it must not be the last option on the line. For example, `(Join:` is treated as the label "(Join" and `(LTrim Join:` is unsupported, but `(Join: C` is okay.

LTrim: Omits spaces and tabs at the beginning of each line. This is primarily used to allow the continuation section to be indented. Also, this option may be turned on for multiple continuation sections by specifying `#LTrim` on a line by itself. `#LTrim` is positional: it affects all continuation sections physically beneath it. The setting may be turned off via `#LTrim Off`.

RTrim0 (RTrim followed by a zero): Turns off the omission of spaces and tabs from the end of each line.

Comments (or Comment or Com or C) [v1.0.45.03+]: Allows semicolon comments inside the continuation section (but not `/*..*/`). Such comments (along with any spaces and tabs to their left) are entirely omitted from the joined result rather than being treated as literal text. Each comment can appear to the right of a line or on a new line by itself.

% (percent sign): Treats percent signs as literal rather than as variable references. This avoids the need to escape each percent sign to make it literal. This option is not needed in places where percent signs are already literal, such as auto-replace hotstrings.

, (comma): Treats commas as delimiters rather than as literal commas. This rarely-used option is necessary only for the commas between command parameters because in function calls, the type of comma does not matter. Also, this option transforms only those commas that actually delimit parameters. In other words, once the command's final parameter is reached (or there are no parameters), subsequent commas are treated as literal commas regardless of this option.

` (accent): Treats each backtick character literally rather than as an escape character. This also prevents commas and percent signs from being explicitly and individually escaped. In addition, it prevents the translation of any explicitly specified escape sequences such as `r and `t.

) [v1.1.01+]: If a closing parenthesis appears in the continuation section's options (except as a parameter of the Join option), the line is reinterpreted as an expression instead of the beginning of a continuation section. This allows expressions like `(x.y)[z]()` to work without the need to escape the opening parenthesis.

Remarks

Escape sequences such as `n (linefeed) and `t (tab) are supported inside the continuation section except when the accent (`) option has been specified.

When the comment option is absent, semicolon and /*..*/ comments are not supported within the interior of a continuation section because they are seen as literal text. However, comments can be included on the bottom and top lines of the section. For example:

    FileAppend,   ; Comment.
    ; Comment.
    ( LTrim Join    ; Comment.
         ; This is not a comment; it is literal. Include the word Comments in the line above to make it a comment.
    ), C:\File.txt   ; Comment.

As a consequence of the above, semicolons never need to be escaped within a continuation section.

A continuation section cannot produce a line whose total length is greater than 16,383 characters (if it tries, the program will alert you the moment the script is launched). One way to work around this is to do a series of concatenations into a variable. For example:

    Var =
    (
    ...
    )
    Var = %Var%`n  ; Add more text to the variable via another continuation section.
    (
    ...
    )
    FileAppend, %Var%, C:\My File.txt

Since a closing parenthesis indicates the end of a continuation section, to have a line start with literal closing parenthesis, precede it with an accent/backtick: ``)`.

A continuation section can be immediately followed by a line containing the open-parenthesis of another continuation section. This allows the options mentioned above to be varied during the course of building a single line.

The piecemeal construction of a continuation section by means of #Include is not supported.

## Convert a Script to an EXE (Ahk2Exe)

A script compiler (courtesy of fincs, with additions by TAC109) is included with the program.

Once a script is compiled, it becomes a standalone executable; that is, AutoHotkey.exe is not required in order to run the script. The compilation process creates an executable file which contains the following: the AutoHotkey interpreter, the script, any files it includes, and any files it has incorporated via the FileInstall command. [v1.1.33+]: Additional files can be included using Compiler Directives.

Ahk2Exe can be used in the following ways:

- GUI Interface: Run the "Convert .ahk to .exe" item in the Start Menu.

- Right-click: Within an open Explorer window, you can right-click any .ahk file and select "Compile Script" (only available if the script compiler option was chosen when AutoHotkey was installed). This creates an EXE file of the same base filename as the script, which appears after a short time in the same directory. Note: The EXE file is produced using the same custom icon, .bin file and compression setting that were last used by Method #1 above.

- Command Line: The compiler can be run from the command line by using the parameters shown below. If any command line parameters are used, the script is compiled immediately unless `/gui` is used.

  Parameter pair | Meaning
  --- | ---
  /in script_name | The path and name of the script to compile. This is mandatory if any other parameters are used, unless `/gui` is used.
  /out exe_name | The path\name of the output .exe to be created. Default is the directory\base_name of the input file plus extension of .exe.
  /icon icon_name | The icon file to be used. Default is the last icon used in the GUI interface.
  /bin file_name | The .bin file to be used. Default is the last .bin file name used in the GUI interface.
  /cp codepage | [v1.1.23.01+]: Overrides the default codepage used to read script files. For a list of possible values, see Code Page Identifiers. Note that Unicode scripts should begin with a byte-order-mark (BOM), rendering the use of this parameter unnecessary.
  /compress n | [v1.1.33+]: Compress the exe? 0 = no, 1 = use MPRESS if present, 2 = use UPX if present. Default is the last setting used in the GUI interface.
  /ahk file_name | [v1.1.33+]: The path\name of AutoHotkey.exe to be used when compiling the script. Default is AutoHotkey.exe in the directory immediately above that containing the compiler. If not there, the installed Autohotkey.exe is used if present. [v1.1.33.01+]: Otherwise AutoHotkeyU32.exe in the directory immediately above that containing the compiler is used.
  /gui | [v1.1.33+]: Show the GUI instead of immediately compiling. The other parameters can be used to override the settings last used in the GUI. `/in` is optional in this case.
  Deprecated: /mpress 0or1 | Compress the exe with MPRESS? 0 = no, 1 = yes. Default is the last setting used in the GUI interface.

  For example:

      Ahk2Exe.exe /in "MyScript.ahk" /icon "MyIcon.ico"

Notes:

- Parameters containing spaces must be enclosed in double quotes.
- Compiling does not typically improve the performance of a script.
- As of v1.1.01, password protection and the /NoDecompile switch are not supported.
- The commands #NoTrayIcon and "Menu, Tray, MainWindow" affect the behavior of compiled scripts.
- The built-in variable A_IsCompiled contains 1 if the script is running in compiled form. Otherwise, it is blank.
- [v1.0.43+]: When parameters are passed to Ahk2Exe, a message indicating the success or failure of the compiling process is written to stdout. Although the message will not appear at the command prompt, it can be "caught" by means such as redirecting output to a file.
- [v1.1.22.03+]: Additionally in the case of a failure, Ahk2Exe has exit codes indicating the kind of error that occurred. These error codes can be found at GitHub (ErrorCodes.md).

The compiler's source code and newer versions can be found at GitHub.

### Script Compiler Directives

[v1.1.33+]: Script compiler directives allow the user to specify details of how a script is to be compiled. Some of the features are:

- Ability to change the version information (such as the name, description, version...).
- Ability to add resources to the compiled script.
- Ability to tweak several miscellaneous aspects of compilation.
- Ability to remove code sections from the compiled script and vice versa.

See Script Compiler Directives for more details.

### Compressing Compiled Scripts

Ahk2Exe optionally uses MPRESS or [v1.1.33+] UPX freeware to compress compiled scripts. If MPRESS.exe and/or UPX.exe has been copied to the "Compiler" subfolder where AutoHotkey was installed, either can be used to compress the .exe as directed by the `/compress` parameter or the GUI setting.

MPRESS official website (downloads and information): http://www.matcode.com/mpress.htm
MPRESS mirror: https://www.autohotkey.com/mpress/

UPX official website (downloads and information): https://upx.github.io/

Note: While compressing the script executable prevents casual inspection of the script's source code using a plain text editor like Notepad or a PE resource editor, it does not prevent the source code from being extracted by tools dedicated to that purpose.

## Passing Command Line Parameters to a Script

Scripts support command line parameters. The format is:

    AutoHotkey.exe [Switches] [Script Filename] [Script Parameters]

And for compiled scripts, the format is:

    CompiledScript.exe [Switches] [Script Parameters]

Switches: Zero or more of the following:

Switch | Meaning | Works compiled?
--- | --- | ---
/f or /force | Launch unconditionally, skipping any warning dialogs. This has the same effect as #SingleInstance Off. | Yes
/r or /restart | Indicate that the script is being restarted (this is also used by the Reload command, internally). | Yes
/ErrorStdOut /ErrorStdOut=Encoding | Send syntax errors that prevent a script from launching to stderr rather than displaying a dialog. See #ErrorStdOut for details. This can be combined with /iLib to validate the script without running it. [v1.1.33+]: An encoding can optionally be specified. For example, `/ErrorStdOut=UTF-8` encodes messages as UTF-8 before writing them to stderr. | Yes
/Debug | [AHK_L 11+]: Connect to a debugging client. For more details, see Interactive Debugging. | No
/CPn | [AHK_L 51+]: Overrides the default codepage used to read script files. For more details, see Script File Codepage. [v1.1.33+]: If "Default to UTF-8" is enabled in the installer, the ".ahk" file type is registered with a command line including `/CP65001`. This causes all scripts launched through the shell (Explorer) to default to UTF-8 in the absence of a UTF-16 byte order mark. Scripts launched by running AutoHotkey.exe directly still default to `CP0`, as the `/CP65001` switch is absent. | No
/iLib "OutFile" | [v1.0.47+]: AutoHotkey loads the script but does not run it. For each script file which is auto-included via the library mechanism, two lines are written to the file specified by OutFile. These lines are written in the following format, where LibDir is the full path of the Lib folder and LibFile is the filename of the library:
    #Include LibDir\
    #IncludeAgain LibDir\LibFile.ahk
If the output file exists, it is overwritten. OutFile can be `*` to write the output to stdout. If the script contains syntax errors, the output file may be empty. The process exit code can be used to detect this condition; if there is a syntax error, the exit code is 2. The /ErrorStdOut switch can be used to suppress or capture the error message. | No

Script Filename: This can be omitted if there are no Script Parameters. If omitted (such as if you run AutoHotkey directly from the Start menu), the program looks for a script file called `AutoHotkey.ahk` in the following locations, in this order:

- The directory which contains the AutoHotkey executable.
- The current user's Documents folder.

The filename `AutoHotkey.ahk` depends on the name of the executable used to run the script. For example, if you rename AutoHotkey.exe to MyScript.exe, it will attempt to find `MyScript.ahk`. If you run AutoHotkeyU32.exe without parameters, it will look for AutoHotkeyU32.ahk.

Note: In old versions prior to revision 51, the program looked for AutoHotkey.ini in the working directory or AutoHotkey.ahk in My Documents.

[v1.1.17+]: Specify an asterisk (*) for the filename to read the script text from standard input (stdin). For an example, see ExecScript().

Script Parameters: The string(s) you want to pass into the script, with each separated from the next by a space. Any parameter that contains spaces should be enclosed in quotation marks. A literal quotation mark may be passed in by preceding it with a backslash (\"). Consequently, any trailing slash in a quoted parameter (such as "C:\My Documents\") is treated as a literal quotation mark (that is, the script would receive the string C:\My Documents"). To remove such quotes, use `StringReplace, 1, 1, ",, All`.

[v1.1.27+]: Incoming parameters, if present, are stored as an array in the built-in variable A_Args, and can be accessed using array syntax. `A_Args[1]` contains the first parameter. The following example exits the script when too few parameters are passed to it:

    if A_Args.Length() < 3
    {
        MsgBox % "This script requires at least 3 parameters but it only received " A_Args.Length() "."
        ExitApp
    }

If the number of parameters passed into a script varies (perhaps due to the user dragging and dropping a set of files onto a script), the following example can be used to extract them one by one:

    for n, param in A_Args  ; For each parameter:
    {
        MsgBox Parameter number %n% is %param%.
    }

If the parameters are file names, the following example can be used to convert them to their case-corrected long names (as stored in the file system), including complete/absolute path:

    for n, GivenPath in A_Args  ; For each parameter (or file dropped onto a script):
    {
        Loop Files, %GivenPath%, FD  ; Include files and directories.
            LongPath := A_LoopFileFullPath
        MsgBox The case-corrected long path name of file`n%GivenPath%`nis:`n%LongPath%
    }

Known limitation: dragging files onto a .ahk script may fail to work properly if 8-dot-3 (short) names have been turned off in an NTFS file system. One work-around is to compile the script then drag the files onto the resulting EXE.

Legacy: The command line parameters are also stored in the variables %1%, %2%, and so on, as in versions prior to [v1.1.27]. In addition, %0% contains the number of parameters passed (0 if none). However, these variables cannot be referenced directly in an expression because they would be seen as numbers rather than variables. The following example exits the script when too few parameters are passed to it:

    if 0 < 3  ; The left side of a non-expression if-statement is always the name of a variable.
    {
        MsgBox This script requires at least 3 incoming parameters but it only received %0%.
        ExitApp
    }

If the number of parameters passed into a script varies (perhaps due to the user dragging and dropping a set of files onto a script), the following example can be used to extract them one by one:

    Loop, %0%  ; For each parameter:
    {
        param := %A_Index%  ; Fetch the contents of the variable whose name is contained in A_Index.
        MsgBox, 4,, Parameter number %A_Index% is %param%.  Continue?
        IfMsgBox, No
            break
    }

If the parameters are file names, the following example can be used to convert them to their case-corrected long names (as stored in the file system), including complete/absolute path:

    Loop %0%  ; For each parameter (or file dropped onto a script):
    {
        GivenPath := %A_Index%  ; Fetch the contents of the variable whose name is contained in A_Index.
        Loop %GivenPath%, 1
            LongPath := A_LoopFileLongPath
        MsgBox The case-corrected long path name of file`n%GivenPath%`nis:`n%LongPath%
    }

## Script File Codepage [AHK_L 51+]

In order for non-ASCII characters to be read correctly from file, the encoding used when the file was saved (typically by the text editor) must match what AutoHotkey uses when it reads the file. If it does not match, characters will be decoded incorrectly. AutoHotkey uses the following rules to decide which encoding to use:

- If the file begins with a UTF-8 or UTF-16 (LE) byte order mark, the appropriate codepage is used and the /CPn switch is ignored.
- If the /CPn switch is passed on the command-line, codepage n is used. For a list of possible values, see Code Page Identifiers.

  Note: The "Default to UTF-8" option in the AutoHotkey [v1.1.33+] installer adds `/CP65001` to the command line for all scripts launched via the shell (Explorer).

- In all other cases, the system default ANSI codepage is used.

Note that this applies only to script files loaded by AutoHotkey, not to file I/O within the script itself. FileEncoding controls the default encoding of files read or written by the script, while IniRead and IniWrite always deal in UTF-16 or ANSI.

As all text is converted (where necessary) to the native string format, characters which are invalid or don't exist in the native codepage are replaced with a placeholder: ANSI '?' or Unicode '�'. In Unicode builds, this should only occur if there are encoding errors in the script file or the codepages used to save and load the file don't match.

RegWrite may be used to set the default for scripts launched from Explorer (e.g. by double-clicking a file):

    ; Uncomment the appropriate line below or leave them all commented to
    ;   reset to the default of the current build.  Modify as necessary:
    ; codepage := 0        ; System default ANSI codepage
    ; codepage := 65001    ; UTF-8
    ; codepage := 1200     ; UTF-16
    ; codepage := 1252     ; ANSI Latin 1; Western European (Windows)
    if (codepage != "")
        codepage := " /CP" . codepage
    cmd="%A_AhkPath%"%codepage% "`%1" `%*
    key=AutoHotkeyScript\Shell\Open\Command
    if A_IsAdmin    ; Set for all users.
        RegWrite, REG_SZ, HKCR, %key%,, %cmd%
    else            ; Set for current user only.
        RegWrite, REG_SZ, HKCU, Software\Classes\%key%,, %cmd%

This assumes AutoHotkey has already been installed. Results may be less than ideal if it has not.

## Debugging a Script

Commands such as ListVars and Pause can help you debug a script. For example, the following two lines, when temporarily inserted at carefully chosen positions, create "break points" in the script:

    ListVars
    Pause

When the script encounters these two lines, it will display the current contents of all variables for your inspection. When you're ready to resume, un-pause the script via the File or Tray menu. The script will then continue until reaching the next "break point" (if any).

It is generally best to insert these "break points" at positions where the active window does not matter to the script, such as immediately before a WinActivate command. This allows the script to properly resume operation when you un-pause it.

The following commands are also useful for debugging: ListLines, KeyHistory, and OutputDebug.

Some common errors, such as typos and missing "global" declarations, can be detected by enabling warnings.

### Interactive Debugging [AHK_L 11+]

Interactive debugging is possible with a supported DBGp client. Typically the following actions are possible:

- Set and remove breakpoints on lines - pause execution when a breakpoint is reached.
- Step through code line by line - step into, over or out of functions and subroutines.
- Inspect all variables or a specific variable.
- View the stack of running subroutines and functions.

Note that this functionality is disabled for compiled scripts.

To enable interactive debugging, first launch a supported debugger client then launch the script with the /Debug command-line switch.

    AutoHotkey.exe /Debug=SERVER:PORT ...

SERVER and PORT may be omitted. For example, the following are equivalent:

    AutoHotkey /Debug "myscript.ahk"
    AutoHotkey /Debug=localhost:9000 "myscript.ahk"

[AHK_L 59+]: To attach the debugger to a script which is already running, send it a message as shown below:

    ScriptPath := "" ; SET THIS TO THE FULL PATH OF THE SCRIPT
    DetectHiddenWindows On
    if WinExist(ScriptPath " ahk_class AutoHotkey")
        ; Optional parameters:
        ;   wParam  = the IPv4 address of the debugger client, as a 32-bit integer.
        ;   lParam  = the port which the debugger client is listening on.
        PostMessage DllCall("RegisterWindowMessage", "str", "AHK_ATTACH_DEBUGGER")

Once the debugger client is connected, it may detach without terminating the script by sending the "detach" DBGp command.

## Script Showcase

See this page for some useful scripts.