# WinExist() / IfWin[Not]Exist

Checks if a matching window exists. If it is, WinExist() returns the Unique ID (HWND) of the first matching window.

## WinExist()

    UniqueID := WinExist(WinTitle , WinText, ExcludeTitle, ExcludeText)

### Parameters

WinTitle

  A window title or other criteria identifying the target window. See WinTitle.

WinText

  If present, this parameter must be a substring from a single text element of the target window (as revealed by the included Window Spy utility). Hidden text elements are detected if DetectHiddenText is ON.

ExcludeTitle

  Windows whose titles include this value will not be considered.

ExcludeText

  Windows whose text include this value will not be considered.

### Return Value

This function returns the Unique ID (HWND) (as hexadecimal integer) of the first matching window (0 if none). Since all non-zero numbers are seen as "true", the statement `if WinExist(WinTitle)` is true whenever WinTitle exists.

### Examples

    if WinExist("ahk_class Notepad") or WinExist("ahk_class" . ClassName)
        WinActivate  ; Uses the last found window.

    MsgBox % "The active window's ID is " . WinExist("A")

    If !WinExist("Calculator")  ; Equivalent to IfWinNotExist, Calculator
        return

## IfWin[Not]Exist

Deprecated: This command is not recommended for use in new scripts. Use the WinExist function instead.

    IfWinExist , WinTitle, WinText, ExcludeTitle, ExcludeText
    IfWinNotExist , WinTitle, WinText, ExcludeTitle, ExcludeText

### Parameters

WinTitle

  A window title or other criteria identifying the target window. See WinTitle.

WinText

  If present, this parameter must be a substring from a single text element of the target window (as revealed by the included Window Spy utility). Hidden text elements are detected if DetectHiddenText is ON.

ExcludeTitle

  Windows whose titles include this value will not be considered.

  Note: Due to backward compatibility, IfWin[Not]Exist interpret this parameter as a command if it exactly matches the name of a command. To work around this, use the WinExist function instead.

ExcludeText

  Windows whose text include this value will not be considered.

### Remarks

SetWinDelay does not apply to this command.

### Examples

    IfWinExist, Untitled - Notepad
    {
        WinActivate  ; Automatically uses the window found above.
        WinMaximize  ; same
        Send, Some text.{Enter}
        return
    }

    IfWinNotExist, Calculator
        return
    else
    {
        WinActivate  ; The above "IfWinNotExist" also set the "last found" window for us.
        WinMove, 40, 40  ; Move it to a new position.
        return
    }

## Remarks

If all parameters are omitted, the Last Found Window will be checked to see if it still exists (or doesn't exist in the case of IfWinNotExist).

If the function or command determines that a qualified window exists, the Last Found Window will be updated to be that window. In other words, if WinExist or IfWinExist evaluates to true or IfWinNotExist evaluates to false, the Last Found Window will be updated.

To discover the HWND of a control (for use with Post/SendMessage or DllCall), use ControlGet Hwnd or MouseGetPos.

Window titles and text are case sensitive. Hidden windows are not detected unless DetectHiddenWindows has been turned on.

## Related

WinActive() / IfWinActive, SetTitleMatchMode, DetectHiddenWindows, Last Found Window, Process, WinActivate, WinWaitActive, WinWait, WinWaitClose, #IfWinActive/Exist