# OnExit

Specifies a callback function or subroutine to run automatically when the script exits.

## OnExit() [v1.1.20+]

    OnExit(Func , AddRemove)

### Parameters

Func

  A function name or function object to call when the script is exiting. The function can optionally define parameters as shown below. If an OnExit function returns a non-zero integer, the script does not exit. Otherwise, the script exits after all registered functions are called.

      ExitFunc(ExitReason, ExitCode)

AddRemove

  One of the following values:
  1 (the default): Call the function after any previously registered functions.
  -1: Call the function before any previously registered functions.
  0: Do not call the function.

  If a label (subroutine) has been registered, it is always called first.

### Remarks

New scripts should use a function instead of a subroutine -- this reduces the risk of accidentally creating a script which can't be exited, and ensures that the exit code passed to Exit or ExitApp is preserved.

Any number of OnExit functions can be registered. If a label (subroutine) is also registered, the functions are called after the subroutine calls ExitApp. An OnExit function usually should not call ExitApp; if it does, the script terminates immediately.

### Examples

    ; After running this script, right click the tray icon and click Exit to test the OnExit callback function.
    #Persistent  ; Prevent the script from exiting automatically.

    ; Register a function to be called on exit:
    OnExit("ExitFunc")

    ; Register an object to be called on exit:
    OnExit(ObjBindMethod(MyObject, "Exiting"))

    ExitFunc(ExitReason, ExitCode)
    {
        if ExitReason not in Logoff,Shutdown
        {
            MsgBox, 4, , Are you sure you want to exit?
            IfMsgBox, No
                return 1  ; OnExit functions must return non-zero to prevent exit.
        }
        ; Do not call ExitApp -- that would prevent other OnExit functions from being called.
    }

    class MyObject
    {
        Exiting()
        {
            MsgBox, MyObject is cleaning up prior to exiting...
            /*
            this.SayGoodbye()
            this.CloseNetworkConnections()
            */
        }
    }

## OnExit

Deprecated: This command is not recommended for use in new scripts. Use the OnExit function instead.

    OnExit , Label

### Parameters

Label

  If omitted, any previously registered label is unregistered. Otherwise, specify the name of the label whose contents will be executed (as a new thread) when the script exits by any means.

### Remarks

IMPORTANT: Since the specified subroutine is called instead of terminating the script, that subroutine must use the ExitApp command if termination is desired.

The built-in variable A_ExitReason is blank unless the OnExit subroutine is currently running or has been called at least once by a prior exit attempt. If not blank, it is one of the words from the table below.

### Examples

    ; After running this script, right click the tray icon and click Exit to test the OnExit subroutine.
    #Persistent  ; Prevent the script from exiting automatically.
    OnExit, ExitSub
    return

    ExitSub:
    if A_ExitReason not in Logoff,Shutdown  ; Avoid spaces around the comma in this line.
    {
        MsgBox, 4, , Are you sure you want to exit?
        IfMsgBox, No
            return
    }
    ExitApp  ; A script with an OnExit subroutine will not terminate unless the subroutine uses ExitApp.

## Remarks

The OnExit callback function or subroutine is called when the script exits by any means (except when it is killed by something like "End Task"). It is also called whenever the #SingleInstance and Reload commands ask a previous instance to terminate.

A script can detect and optionally abort a system shutdown or logoff via `OnMessage(0x11, "WM_QUERYENDSESSION")` (see OnMessage example #2 for a working script).

The OnExit thread does not obey #MaxThreads (it will always launch when needed). In addition, while it is running, it cannot be interrupted by any thread, including hotkeys, custom menu items, and timed subroutines. However, it will be interrupted (and the script will terminate) if the user chooses Exit from the tray menu or main menu, or the script is asked to terminate as a result of Reload or #SingleInstance. Because of this, the OnExit callback function or subroutine should be designed to finish quickly unless the user is aware of what it is doing.

If the OnExit thread encounters a failure condition such as a runtime error, the script will terminate. This prevents a flawed OnExit callback function or subroutine from making a script impossible to terminate.

If the OnExit thread was launched due to an Exit or ExitApp command that specified an exit code, in [v1.1.19] and earlier that code is ignored and no longer available. In [v1.1.20+] the initial exit code is used unless overridden by calling ExitApp with a new exit code.

Whenever an exit attempt is made, each OnExit callback function or subroutine starts off fresh with the default values for settings such as SendMode. These defaults can be changed in the auto-execute section.

## Exit Reasons

Logoff | The user is logging off.
Shutdown | The system is being shut down or restarted, such as by the Shutdown command.
Close | The script was sent a WM_CLOSE or WM_QUIT message, had a critical error, or is being closed in some other way. Although all of these are unusual, WM_CLOSE might be caused by WinClose having been used on the script's main window. To close (hide) the window without terminating the script, use WinHide.
Error | A runtime error occurred in a script that has no hotkeys and that is not persistent. An example of a runtime error is Run/RunWait being unable to launch the specified program or document.
Menu | The user selected Exit from the main window's menu or from the standard tray menu.
Exit | The Exit or ExitApp command was used (includes custom menu items).
Reload | The script is being reloaded via the Reload command or menu item.
Single | The script is being replaced by a new instance of itself as a result of #SingleInstance.

## Related

OnError(), OnMessage(), RegisterCallback(), OnClipboardChange, ExitApp, Shutdown, #Persistent, Threads, Gosub, Return, Menu