# If (Expression)

Specifies one or more statements to execute if an expression evaluates to true.

    If (Expression)
    {
        Statements
    }

## Remarks

An If statement that contains an expression is usually differentiated from a traditional If statement such as `if FoundColor != Blue` by enclosing the expression in parentheses, as in `if (FoundColor != "Blue")`. However, this is not strictly required, as any If statement which does not match any of the legacy if patterns is assumed to contain an expression. In particular, the following are also common ways of writing an If (expression):

- Starting with an open parenthesis but not fully enclosing the expression: `if (x > 0) and (y > 0)`
- Starting with a function call: `if InStr(a, b)`
- Starting with an operator such as `not` or `!`: `if !MyVar`

Known limitation: For historical reasons, If (expression) actually accepts a numeric parameter rather than a pure expression. For example, `if %MyVar%` is equivalent to `if MyVar`. This can be avoided by always enclosing the expression in parentheses.

If the If statement's expression evaluates to true (which is any result other than an empty string or the number 0), the line or block underneath it is executed. Otherwise, if there is a corresponding Else statement, execution jumps to the line or block underneath it.

If an If owns more than one line, those lines must be enclosed in braces (to create a block). However, if only one line belongs to an If, the braces are optional. See the examples at the bottom of this page.

The space after `if` is optional if the expression starts with an open-parenthesis, as in `if(expression)`.

The One True Brace (OTB) style may optionally be used with If statements that are expressions (but not traditional If statements). For example:

    if (x < y) {
        ; ...
    }
    if WinExist("Untitled - Notepad") {
        WinActivate
    }
    if IsDone {
        ; ...
    } else {
        ; ...
    }

Unlike an If statement, an Else statement supports any type of statement immediately to its right.

On a related note, the statement `if Var between LowerBound and UpperBound` checks whether a variable is between two values, and `if Var in MatchList` can be used to check whether a variable's contents exist within a list of values.

## Related

Expressions, Assign expression (:=), if var in/contains, if var between, IfInString, Blocks, Else, While-loop

## Examples

#1

    if (A_Index > 100)
        return

    if (A_TickCount - StartTime > 2*MaxTime + 100)
    {
        MsgBox Too much time has passed.
        ExitApp
    }

    if (Color = "Blue" or Color = "White")
    {
        MsgBox The color is one of the allowed values.
        ExitApp
    }
    else if (Color = "Silver")
    {
        MsgBox Silver is not an allowed color.
        return
    }
    else
    {
        MsgBox This color is not recognized.
        ExitApp
    }

#2: A single multi-statement line does not need to be enclosed in braces.

    MyVar := 3
    if (MyVar > 2)
        MyVar++, MyVar := MyVar - 4, MyVar .= " test"
    MsgBox % MyVar  ; Shows "0 test".