# FileMove

Moves or renames one or more files.

    FileMove, SourcePattern, DestPattern , Overwrite

## Parameters

SourcePattern

  The name of a single file or a wildcard pattern such as C:\Temp\*.tmp. SourcePattern is assumed to be in %A_WorkingDir% if an absolute path isn't specified.

DestPattern

  The name or pattern of the destination, which is assumed to be in %A_WorkingDir% if an absolute path isn't specified.

  If present, the first asterisk (`*`) in the filename is replaced with the source filename excluding its extension, while the first asterisk after the last full stop (`.`) is replaced with the source file's extension. If an asterisk is present but the extension is omitted, the source file's extension is used.

  To perform a simple move -- retaining the existing file name(s) -- specify only the folder name as shown in these mostly equivalent examples:

      FileMove, C:\*.txt, C:\My Folder

      FileMove, C:\*.txt, C:\My Folder\*.*

  The destination directory must already exist. If My Folder does not exist, the first example above will use "My Folder" as the target filename, while the second example will move no files.

Overwrite

  This parameter determines whether to overwrite files if they already exist. If this parameter is 1 (true), the command overwrites existing files. If omitted or 0 (false), the command does not overwrite existing files.

  This parameter can be an expression, even one that evalutes to true or false (since true and false are stored internally as 1 and 0).

## Error Handling

[v1.1.04+]: This command is able to throw an exception on failure. For more information, see Runtime Errors.

ErrorLevel is set to the number of files that could not be moved due to an error, or 0 otherwise. However, if the source file is a single file (no wildcards) and it does not exist, ErrorLevel is set to 0. To detect this condition, use FileExist() or IfExist on the source file prior to moving it.

Unlike FileCopy, moving a file onto itself is always considered successful, even if the overwrite mode is not in effect.

If files were found, A_LastError is set to 0 (zero) or the result of the operating system's GetLastError() function immediately after the last failure. Otherwise A_LastError contains an error code that might indicate why no files were found.

## Remarks

FileMove moves files only. To instead move the contents of a folder (all its files and subfolders), see the examples section below. To move or rename a single folder, use FileMoveDir.

The operation will continue even if error(s) are encountered.

Although this command is capable of moving files to a different volume, the operation will take longer than a same-volume move. This is because a same-volume move is similar to a rename, and therefore much faster.

## Related

FileCopy, FileCopyDir, FileMoveDir, FileDelete

## Examples

#1

    FileMove, C:\My Documents\List1.txt, D:\Main Backup\  ; Move the file without renaming it.
    FileMove, C:\File Before.txt, C:\File After.txt  ; Rename a single file.
    FileMove, C:\Folder1\*.txt, D:\New Folder\*.bkp  ; Move and rename files to a new extension.

#2: The following example moves all files and folders inside a folder to a different folder:

    ErrorCount := MoveFilesAndFolders("C:\My Folder\*.*", "D:\Folder to receive all files & folders")
    if (ErrorCount != 0)
        MsgBox %ErrorCount% files/folders could not be moved.

    MoveFilesAndFolders(SourcePattern, DestinationFolder, DoOverwrite = false)
    ; Moves all files and folders matching SourcePattern into the folder named DestinationFolder and
    ; returns the number of files/folders that could not be moved. This function requires [v1.0.38+]
    ; because it uses FileMoveDir's mode 2.
    {
        if (DoOverwrite = 1)
            DoOverwrite := 2  ; See FileMoveDir for description of mode 2 vs. 1.
        ; First move all the files (but not the folders):
        FileMove, %SourcePattern%, %DestinationFolder%, %DoOverwrite%
        ErrorCount := ErrorLevel
        ; Now move all the folders:
        Loop, %SourcePattern%, 2  ; 2 means "retrieve folders only".
        {
            FileMoveDir, %A_LoopFileFullPath%, %DestinationFolder%\%A_LoopFileName%, %DoOverwrite%
            ErrorCount += ErrorLevel
            if ErrorLevel  ; Report each problem folder by name.
                MsgBox Could not move %A_LoopFileFullPath% into %DestinationFolder%.
        }
        return ErrorCount
    }