.PS
# OpampDPV.m4
cct_init(svg_font(sans-serif,11bp__))

  A: opamp(,,, body=shaded "yellow")
     thinlines_
      `"opamp(,,,"' wid 0.65 ljust at A.sw-(0.4,0.4) \
        `"body=shaded \"yellow\")"' ljust
      `"Out"' below at A.Out
       spline <- from A.In1 left 0.1 then up 0.1 left 0.1
        `"In1"' wid 0.25 rjust above
       spline <- from A.In2 left 0.1 then down 0.1 left 0.1
        `"In2"' rjust below
       arrow <- up 0.1 right 0.1 from A.N
        `"N"' ljust above
       arrow <- up 0.1 right 0.1 from A.E1
        `"E1"' ljust above
       arrow <- up 0.1 right 0.1 from A.E
        `"E"' ljust above
       arrow <- down 0.1 right 0.1 from A.E2
        `"E2"' ljust below
       arrow <- down 0.1 right 0.1 from A.S
        `"S"' ljust below
       arrow <- left 0.2 from A.W
        `"W"' rjust
     thicklines_
     Point_(90)
  B: opamp(,,,,PR) with .sw at A.se+(0.5,0)
     thinlines_
      `"Point_(90);"' ljust at B.sw-(0,0.2) \
      `"opamp(,,,,PR)"' ljust
       spline <- left arrowht down arrowht from B.V1 then left 0.1
        `"V1"' rjust
       spline <- right arrowht down arrowht from B.V2 then right 0.1
        `"V2"' ljust
     thicklines_
     right_
  C: opamp(right_ dimen_*2,` ',` ',dimen_*7/4,R,
      X1: 2/3 between S and N
      X2: 1/3 between S and N
       pushdef(`dimen_',dimen_/2); thinlines_; textht /= 2
       line from X1 to X1+(dimen_/3,0); A1:Here; corner
       line from X2 to X2+(dimen_/3,0); A2:Here; corner
      Ri: resistor(up_ to A1)
       "svg_it(R`'svg_sub(i))" wid 5bp__ with .w at Ri+(2bp__,0)
      Cs: consource(up_ dimen_ at Ri+(dimen_,0)); corner; {"+" at Cs "-"
       ground(at Cs.start,T)
       "svg_it(Av`'svg_sub(d))" wid 9bp__ with .w at last [].se+(-2bp__,2bp__)}
      Ro: resistor(right_ dimen_*7/8)
       {"svg_it(R`'svg_sub(o))"  wid 9bp__ with .se at last [].nw+(3bp__,1bp__)}
       line to (Here,E) then to E
       textht *=2 ; thicklines_; popdef(`dimen_')
      ) with .sw at B.se+(0.75,0)
      `"opamp(...)"' at C.s+(-0.2,-0.15)
      dot(at C.Out,,1); "svg_it(v`'svg_sub(out))" with .n at last [].s
      line from C.X1 left_ dimen_/3
      gap(down_ C.X1.y-C.X2.y,1); rlabel(+,svg_it(v`'svg_sub(d)),-)
      line to C.X2 chop dotrad_ chop 0
  D: opamp(,,,body=shaded "orange",T) with .sw at C.se+(0.25,0)
      `"opamp(,,,"' wid 0.85 ljust at D.sw+(0,-0.25) \
         `"body=shaded \"orange\",T)"' wid 1.75 ljust

 command `"</g>"' # end font
.PE